POPSブログ

サイン曲線で画像を動かすテストです/2

92

  Category:  as32012/04/22 pops 

サイン曲線で画像を動かすテストです2、文字を動かしたものを改造して、シュミュレーションテストをしてみました。
画像を自由配置出来るようにして、縮小出来るようにもしました。


サイン曲線で画像を動かすテスト2

記事、「文字を分解してアニメ処理で表示9」の文字を動かしたものを改造して、画像を埋め込みましたので動きは文字の場合と同じです。
さらに画像を自由配置出来るようにして、縮小出来るようにもしました。



注意、FlashTest190c.swf、は画像を読み込んでいるため、当方専用になります。/main/images/xxx.jpg


簡単な動作の説明

説明図


1.sin cos関数により上下方向に振動を与え、右より左に移動しているだけです。(Outは反対)
2.Y軸およびX軸で反転させて、方向を違わせています。ここでは位相の切り替えと呼んでいます。
3.アニメ処理はdelay値を変えるためのみ使用され、波形運動はonEnterFrameで処理します。
4.画像のSpriteを運動用のSpriteの中に入れてonEnterFrame処理しています。パーテクルのようなものです。
5.運動用のSpriteの変数をも使用していますので、少し判りにくいかも知れません。
6.直線運動のものと組み合わせる場合はかなり面倒です。(これで直線運動も可能ですが)
7.上記はIn Outの例ですが、Outの場合は処理を反対にすればよい事になります。
8.In Out一括にまとめることも可能ですが、OutのonEnterFrameは別に処理しました。
9.注意、「サイン曲線で画像を動かすテスト1」のものと少々ちがいます。
10.画像を自由配置出来るようにして、縮小出来るようにもしました。拠り実用的です。


注意、使用者の環境により画像パスを変更ください。


AS3

FlashTest190c.as


//動く画像表示テスト
//FlashTest190c
//640x480
//sin関数/In Out

package
{
	
	import flash.display.*;
	import flash.events.*;
	import flash.net.*;
	import flash.geom.*;
	import flash.system.*;
	import flash.utils.*;
	import flash.text.*;
	import flash.filters.DropShadowFilter;
	
	//TweenLite
	import com.greensock.*;
	import com.greensock.easing.*;
	
	//虹色用
	import frocessing.color.ColorHSV;

	[SWF(width="640", height="480", frameRate="30", backgroundColor="0xFFFFFF")]

	public class FlashTest190c extends Sprite
	{
		
		static public const	INTERPOLATE:Number = 50;
		
		private var backlayer:Sprite;
		private var layer1:Sprite;
		private var layer3:Sprite;
		private var layer4:Sprite;
		private var layer5:Sprite;
		private var container:Sprite;
		private var text_container:Sprite;
		
		//TEXT
		private var txfcolor:uint = 0x6496ED;
		private var tf:TextField;
		private var tf_names:Array = ["通常","1","通常","並び順","位相 0","回転 0","番号 0","初期位置","500"]
		private var hittf:Array = [];
		//BTN
		private var btn_names:Array = ["透過切替", "拡大切替", "遅延反転", "順序切替", "位相切替", "回転切替", "番号切替", "動作切替", "距離切替"];
		private var hitbtn:Array = [];
		private var fuc_names:Array = [alpha_chg, scale_chg, inversion_chg, delay_chg, xy_chg, rotat_chg, number_chg, setpoint_chg, distance_chg];
		private var btn_1:Sprite;
		private var btn_2:Sprite;
		private var btn_3:Sprite;
		private var btn_4:Sprite;
		private var btn_5:Sprite;
		private var btn_6:Sprite;
		
		//container位置
		private var container_x:Number = 100;
		private var container_y:Number = 300;
		
		//MOVE-IMAGE
		private var photomax:int;
		
		//格納容器2、画像専用なので名前をかえた
		private var img_sps:Array = [];//要素Sprite格納容器
		private var img_cxs:Array = [];//X位置格納容器
		private var img_cys:Array = [];//Y位置格納容器
		private var sin_balls:Array = [];//要素bez_ball格納容器
		private var count_sin:Array = [];//INTERPOLATE減算用配列
				
		//個別に初期位置を同一にする/1=強制移動 0=移動しない
		private var firstPoint:int = 0;
		private var txs:Array = new Array('固定位置','移動位置');
		private var no:int = 0;
		private var rotatno:int = 0;
		private var rot:Array = [0, 360, -360, 270, -270];
		private var rot_v:Number = 0;//回転数
		//逆転係数
		private var chg_x:Number = 1;
		private var chg_y:Number = 1;
		private var chg_xyno:Number = 0;
		//順序切り替え
		private var delay_no:int = 0;
		private var delay_nm:Array = new Array('並び順', '反対順', '中から', '外から');
		//グローバルカウント/delayが終了したかの判定に使用する、複数のアニメを同時進行の場合は複数個必要だ
		private var gl_count:int = 0;
		//背景番号
		private var back_no:int = 0;
		private var backcolors:Array = new Array(0x000000,0xFFFFFF,0xF0F0F0,0xF1EBE7,0xD4DFE8,0x808080);
		//振幅
		private var swing_x:Number = 100;
		private var swing_y:Number = 100;
		//距離
		private var ball_len_x:Number = 500;//350
		private var ball_len_y:Number = 500;//350
		private var balllen_no:int = 0;
		private var balllen_nm:Array = [500, 300, 150];
		//遅延反転
		private var inversion_v:int = 0;
		private var inversion_nm:Array = new Array('通常動作', '交互遅延', '交互反転');
		//scale alpha
		private var scaleUp:Boolean = false;//scaleUpするか判定
		private var scale_v:Number = 1;
		private var scale_no:int = 0;
		private var scale_nm:Array = new Array(1, 1.5, 2, 2.5, 5, 1, 0.5, 0);
		private var alpha_v:Number = 1;//注意固定値
		private var alpha_flag:Number = 0;//alphaを変えるか
		private var alpha_no:int = 0;
		private var alpha_nm:Array = new Array('通常', '透過');
		
		//No5の進む角度標準3.6/画像なので遅くした、小さくすると遅くなる
		private var angle5:Number = 2.4;//3.6
		//OUT実行判定フラグ
		private var outflag:Boolean = false;
		//画像のおおきさ
		private var image_W:Number = 80;
		private var image_H:Number = 60;
		
		//LOADER
		private var loader:Loader;
		//Loading
		private var indicator:DisplayObject;
		//現在表示画像配列番号
		private var countImage:int = 0;
		//画像Bitmap
		private var mainImages:Array = [];//Array-Bitmap
		//画像収容Sprite
		private var mainImageBox:Sprite;
		//URL
		private var imageUrls:Array = [];
		//画像位置保存用	
		private var _arrX:Array = [];//X位置保存
		private var _arrY:Array = [];//Y位置保存
		private var _arrW:Array = [];//幅保存
		private var _arrH:Array = [];//高さ保存
		//Filter
		private var shade:DropShadowFilter;
		//画像配置の種類
		private var place_no:int = 0;
		private var keep_place_no:int = 0;
		private var place_no_mn:Array = ["横に並べる", "縦に並べる", "横に重ねる"];
		
		public function FlashTest190c():void {
			
			//回転数
			rot_v = rot[rotatno];
			//BASE/黒背景
			graphics.beginFill(0x000000);//0x000000
			graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
			graphics.endFill();
			
			//白背景レーヤー
			backlayer = createSquare(0, 0, stage.stageWidth, stage.stageHeight, 0x000000, 1);
			addChild(backlayer);
			
			//layer1 文字関係をまとめた
			layer1 = new Sprite();
			addChild(layer1);
			//text
			tf = createTextField(10, 460, stage.stageWidth - 20, 20);
			tf.textColor = txfcolor;
			tf.text = "";
			tf.selectable = false;
			layer1.addChild(tf);
			
			//ボタンレーヤー
			layer3 = new Sprite();
			addChild(layer3);
			
			//ボタン
			var i:int = 0;
			for (i = 0; i < btn_names.length; i++) {
				var btn:RoundBtn = new RoundBtn(btn_names[i], 13, 0x000000, 60, 20, 0xCCCCCC, 1, 5);
				btn.x = i * 70 + 40;
				btn.y = 15;
				hitbtn[i] = btn;
				layer3.addChild(hitbtn[i]);
				hitbtn[i].addEventListener( MouseEvent.CLICK, fuc_names[i] );
			}
			
			//BTN-1/アニメIN実行
			btn_1 = createRoundBTN("アニメIN", 13, 0x000000, 60, 20, 0xFF69B4, 1, 5);
			btn_1.x = 600;
			btn_1.y = 65;//40
			layer3.addChild(btn_1);
			layer3.visible = false;
			//btn_1にListenerを設定
			btn_1.addEventListener( MouseEvent.CLICK, animate2 );
			
			//BTN-3/アニメOUT実行
			btn_3 = createRoundBTN("アニメOUT", 13, 0x000000, 60, 20, 0x48D1CC, 1, 5);
			btn_3.x = 530;
			btn_3.y = 65;//40
			layer3.addChild(btn_3);
			//btn_3にListenerを設定
			btn_3.addEventListener( MouseEvent.CLICK, animate3 );
			
			//BTN-6/再表示layer3
			btn_6 = createRoundBTN("再表示", 13, 0x000000, 60, 20, 0x87CEFA, 1, 5);
			btn_6.x = 460;
			btn_6.y = 65;
			layer3.addChild(btn_6);
			//btn_6にListenerを設定
			btn_6.addEventListener( MouseEvent.CLICK, show_img );
			
			//BTN-2/背景切り替え
			layer4 = new Sprite();
			addChild(layer4);
			layer4.visible = false;
			
			btn_2 = createRoundBTN("背景切替", 13, 0x000000, 60, 20, 0xCCCCCC, 1, 5);
			btn_2.x = 600;
			btn_2.y = 465;
			layer4.addChild(btn_2);
			//btn_2にListenerを設定
			btn_2.addEventListener( MouseEvent.CLICK, back_chg );
			
			//BTN-4/配置位置切り替え
			btn_4 = createRoundBTN("配置位置", 13, 0x000000, 60, 20, 0xCCCCCC, 1, 5);
			btn_4.x = 460;
			btn_4.y = 465;
			layer4.addChild(btn_4);
			//btn_4にListenerを設定
			btn_4.addEventListener( MouseEvent.CLICK, place_chg );
			
			//BTN-5/配置位置切り替え実行
			btn_5 = createRoundBTN("変更実行", 13, 0x000000, 60, 20, 0xFFE4E1, 1, 5);
			btn_5.x = 530;
			btn_5.y = 465;
			layer4.addChild(btn_5);
			//btn_5にListenerを設定
			btn_5.addEventListener( MouseEvent.CLICK, place_reset );
			
			//TEXTレーヤー
			layer5 = new Sprite();
			addChild(layer5);
			//text
			for (i = 0; i < tf_names.length; i++) {
				hittf[i] = createTextField(0, 0, 60, 20);
				hittf[i].x = i * 70 + 10;
				hittf[i].y = 30;
				hittf[i].textColor = txfcolor;
				hittf[i].text = tf_names[i];
				layer5.addChild(hittf[i]);
			}
			
			//MOVE文字container/ドラッグがテキストにじゃまされて聞きにくいので上にした
			container = createSquare(0, 0, stage.stageWidth, 10, 0x000000, 0);
			container.x = container_x;
			container.y = container_y;
			addChild(container);
			//文字種をかえてtext_container削除するために入れる通常は不要
			
			//LOADING
			indicator = new Indicator();
			indicator.x = 12;
			indicator.y = 15;
			indicator.addEventListener(Event.ENTER_FRAME, step);//回転Listener
			addChild(indicator);
			indicator.visible = false;
			
			//goto-init
			init();
		}
		
		// INIT
		private function init():void {
			
			//drag-Listener/container
			container.addEventListener(MouseEvent.MOUSE_DOWN, onFileMouseDown);
			container.addEventListener(MouseEvent.MOUSE_UP, onFileMouseUp);
			//goto-main
			main_action();
		}
		
		// MAIN-ACTION ここでは、どうしても必要では無い
		private function main_action():void {
			//main_action as3 hear
			//GOTO-URL-SET、画像読み込みに進む
			loadImage_Url_Set();
		}
		
		// 画像URL-SET
		private function loadImage_Url_Set():void
		{
			//画像URL 80x60
			imageUrls = [
				"/main/images/photo_bz1.jpg",
				"/main/images/photo_bz2.jpg",
				"/main/images/photo_bz3.jpg",
				"/main/images/photo_bz4.jpg",
				"/main/images/photo_bz5.jpg"
			];
			
			//カウント
			countImage = 0;
			//画像数
			photomax = imageUrls.length;
			//LOADING表示
			indicator.visible = true;
			//GOTO-loadImage
			loadImage();
		}
		// 画像をロード
		private function loadImage():void {
			//loaderセット
			loader = new Loader();
			var imageName:String = imageUrls[countImage];
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete_img);
			loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);//Error
			loader.load(new URLRequest(imageName));//loader
		}

		private function onComplete_img(event:Event):void {
			loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, onComplete_img);
			tf.text = "画像読み込み中";
			
			//画像の加工保存
			//Matrixを使用した場合
			var mainloader:Loader = event.currentTarget.loader;
			var ratio:Number = image_W / loader.width;//縮尺比率
			var matrix:Matrix = new Matrix();
			matrix.scale(ratio, ratio);
			var bd2:BitmapData = new BitmapData(image_W, image_H, false);
			bd2.draw(mainloader, matrix);//Matrixを適応
			mainImages.push(bd2);
			
			//画像大きさ受け渡し
			_arrW.push(event.target.content.width);
			_arrH.push(event.target.content.height);
			
			countImage ++;
			
			//全て読み込んだら画像の加工に、まだなら残り画像をロードする
			if (countImage >= photomax) {
				//LOADING非表示
				indicator.visible = false;
				//画像をロード終了、画像運動表示に進む
				make_ImageBox();
				
			} else {
				//残り画像をLoad
				loadImage();
			}
			
		}
		
		//画像運動表示
		private function make_ImageBox():void {
			
			//max再計算、push操作しているので、画像取得出来無かったものははぶかれている
			photomax = mainImages.length;
			//Filter作成
			shade = new DropShadowFilter(1, 90, 0x000000, 0.4, 4, 4, 2, 3, false, false);
			var allpoint:Number = 0;
			var i:int = 0;
			for (i = 0; i < photomax; i++) {
				
				//SinBall運動CLASSを作る
				var ball:SinBall = new SinBall();
				
				//2重構造でないと中心補正が出来ないので収容インナーを作り画像を流す
				//画像収容インナー
				var spss_in:Sprite = new Sprite();
				spss_in.graphics.beginBitmapFill(mainImages[i], null, false, false);
				spss_in.graphics.drawRoundRect(0, 0, _arrW[i], _arrH[i], 10);
				spss_in.graphics.endFill();
				spss_in.x = _arrW[i] / -2;
				spss_in.y = _arrH[i] / -2;
				//中心補正のSprite
				var spss:Sprite = new Sprite();
				spss.filters = [shade];//filter
				spss.addChild(spss_in);
				//配列に保存addChild
				img_sps[i] = spss;
				ball.addChild(img_sps[i]);
				
				//識別番号をいれる
				ball.count_no = i;
				sin_balls[i] = ball;
				
				//ここでは初期は横並びとして、横に並べるために、X位置を計算する
				//予め計算した配列情報を利用しても良い
				allpoint += _arrW[i]/2;
				img_cxs[i] = allpoint;
				img_cys[i] = 0;//Yは0
				//間隔プラス
				allpoint += (_arrW[i] / 2 + 10);
				
				//横並びの画像列位置確定/アニメしないならば一応ここで並んでいる
				img_sps[i].x = img_cxs[i];
				img_sps[i].y = img_cys[i];
				//コンテナにaddChildする
				container.addChild(ball);
				//
			}
			
			//GOTO-animate
			animate2();
			
		}
		
		//透過切り替え
		private function alpha_chg(e:MouseEvent):void {
			alpha_no ++;
			if (alpha_no > 1) { alpha_no = 0; }
			if (alpha_no == 0 ) { alpha_flag = 0; }
			if (alpha_no == 1 ) { alpha_flag = 1; }
			hittf[0].text = "" + alpha_nm[alpha_no];
		}
		//拡大切り替え
		private function scale_chg(e:MouseEvent):void {
			scale_no ++;
			if (scale_no > 7) { scale_no = 0; }
			scale_v = scale_nm[scale_no];
			hittf[1].text = "" + scale_v;
		}
		//反転遅延
		private function inversion_chg(e:MouseEvent):void {
			inversion_v ++;
			if (inversion_v > 2) { inversion_v = 0; }
			hittf[2].text = "" + inversion_nm[inversion_v];
		}
		//順序切り替え
		private function delay_chg(e:MouseEvent):void {
			delay_no ++;
			if (delay_no > 3) { delay_no = 0; }
			hittf[3].text = "" + delay_nm[delay_no];
		}
		//位相切り替え
		private function xy_chg(e:MouseEvent):void {
			chg_xyno ++;
			if (chg_xyno > 3) { chg_xyno = 0; }
			//位相切り替え
			if (chg_xyno == 0) { chg_x = 1; chg_y = 1; }
			if (chg_xyno == 1) { chg_x = 1; chg_y = -1; }
			if (chg_xyno == 2) { chg_x = -1; chg_y = 1; }
			if (chg_xyno == 3) { chg_x = -1; chg_y = -1; }
			hittf[4].text = "" + chg_xyno;
		}
		//回転切り替え
		private function rotat_chg(e:MouseEvent):void {
			//0 360 -360 180 -180
			rotatno ++;
			if (rotatno > 4 ) { rotatno = 0; }
			rot_v = rot[rotatno];
			hittf[5].text = "" + rot_v;
		}
		//番号切り替え
		private function number_chg(e:MouseEvent):void {
			//0-5 5螺旋
			no ++;
			if (no > 5 ) { no = 0; }
			hittf[6].text = "" + no;
		}
		//初期位置切り替え
		private function setpoint_chg(e:MouseEvent):void {
			//
			firstPoint ++;
			if (firstPoint > 1) { firstPoint = 0; }
			//if (firstPoint == 1) { firstPoint = 0; } else { firstPoint = 1; }
			hittf[7].text = "" + txs[firstPoint];
		}
		//距離切り替え
		private function distance_chg(e:MouseEvent):void {
			balllen_no ++;
			if (balllen_no > 2) { balllen_no = 0; }
			ball_len_x = balllen_nm[balllen_no] * 1;
			ball_len_y = balllen_nm[balllen_no] * 1;
			hittf[8].text = "" + balllen_nm[balllen_no];
		}
		//背景切り替え
		private function back_chg(e:MouseEvent):void {
			back_no ++;
			if (back_no > 5 ) { back_no = 0; }
			back_colorchg(backcolors[back_no]);
		}
		//背景切り替え実行
		private function back_colorchg(bcolor:uint):void {
			backlayer.graphics.clear();
			backlayer.graphics.beginFill(bcolor);//0x000000
			backlayer.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
			backlayer.graphics.endFill();
		}
		//配置位置切り替え
		private function place_chg(e:MouseEvent):void {
		place_no ++;
		if (place_no > 2) { place_no = 0; }
		tf.text = "配置位置 [ " + place_no_mn[place_no] + "] 実行は[変更実行]ボタンを押す";
		}
		//配置位置切り替え実行
		private function place_reset(e:MouseEvent):void {
			//同じなら実行しない
			if (keep_place_no == place_no) { tf.text = "現在設定と同一のため位置切り替え中止"; return; }
			keep_place_no = place_no;
			tf.text = "配置位置 [ " + place_no_mn[place_no] + " ] に変更しました";
			
			var allpoint:Number = 0;
			var i:int = 0;
			for (i = 0; i < photomax; i++) {
				if (place_no == 0) {
					//横に並べるX位置
					allpoint += _arrW[i]/2;
					img_cxs[i] = allpoint;
					img_cys[i] = 0;//Yは0
					//間隔プラス
					allpoint += (_arrW[i] / 2 + 10);
				}
				if (place_no == 1) {
					//縦に並べるY位置
					allpoint += _arrH[i]/2;
					img_cxs[i] = _arrW[i]/2;
					img_cys[i] = allpoint;
					//間隔プラス
					allpoint += (_arrH[i] / 2 + 10);
				}
				if (place_no == 2) {
					//横に重ねる、配置の位置などは自由にできる、位置情報を配列に入れるだけ
					img_cxs[i] = i*_arrW[i]/2;
					img_cys[i] = 0;
				}
				//再表示に進む、位置情報を配列に入れるだけね良いのだが、一応表示してみる
				show_img();
			}
		}
		
		//animate2/IN
		private function animate2( e:MouseEvent = null ):void {
			
			tf.text = "SIN曲線 アニメ IN 実行中です [" + place_no_mn[place_no] + "]";
			//OUT実行判定フラグ
			outflag = false;
			
			//ボタン非表示/アニメ途中おされるとくるう
			layer3.visible = false;
			layer4.visible = false;
			
			//no = Math.random() * 6;
			//順序切り替え
			var delay_v:Number = 0;
			var delay_total:Number = photomax * 0.5;
			var txline_mv:Number = (photomax - 1) / 2;
			var flag3:int = 1;
			//alpha
			var alpha_v2:Number = 1;
			//変化の確率 inversion_v
			//var chgflag:Number = Math.floor(Math.random() * 6);
			//中外の場合加算する数値
			var d_chg_v:Number = Math.floor(Math.random() * 4 ) * 0.25;
			//alpha
			if (alpha_flag == 0 ) { alpha_v2 = 1; }
			if (alpha_flag == 1 ) { alpha_v2 = 0; }
			
			var i:int = 0;
			for (i = 0; i < photomax; i++) {
				
				//中の文字位置を00にセットする位置情報は外のspiral_ballsに設定した
				//回転のため
				img_sps[i].x = 0;
				img_sps[i].y = 0;
				
				//見えない場用に移動/2倍にしないと見える場合あり
				sin_balls[i].x = (stage.stageWidth + ball_len_x + img_cxs[i]) * chg_x;
				sin_balls[i].y = img_cys[i];
				
				//scale/画像だから0で良い
				sin_balls[i].scaleX = 0;
				sin_balls[i].scaleY = 0;
				
				//INTERPOLATE減算用配列
				count_sin[i] = INTERPOLATE;//50
				
				//delay値の変化/中外4種類
				delay_v = i * 0.5;//左
				if (delay_no == 1) { delay_v = delay_total - i * 0.5; }//右
				if (delay_no == 2) { delay_v = Math.abs((i + d_chg_v) - txline_mv)*0.5; }//中
				if (delay_no == 3) { delay_v = (delay_total / 2) - Math.abs((i + d_chg_v) - txline_mv) * 0.5; }//外
				
				//遅延フラグクリア
				sin_balls[i]._chg_x = 1;
				sin_balls[i]._chg_y = 1;
				
				//遅延inversion_v/chgflag
				if (inversion_v == 1) {
					if (flag3 < 0) { delay_v += 2.25; }
				}
				//逆転inversion_v/chgflag
				if (inversion_v == 2) {
					if (flag3 < 0) {
						sin_balls[i]._chg_x = -1;
						sin_balls[i]._chg_y = -1;
					}
				}
				
				//scaleUpするか判定
				scaleUp = false;
				if (scale_v < 1) { scaleUp = true;}
				
				//グローバルカウント
				gl_count = 0;
				
				//TEST sin
				sin_balls[i].radian = 0;
				//振幅
				swing_y = Math.floor(Math.random() * 5) * 10 + 50;
				
				//中を拡大する/外側拡大では正確にならない
				img_sps[i].scaleX = scale_v;
				img_sps[i].scaleY = scale_v;
				
				//遅延させるTweenLite
				var myTween:TweenLite = new TweenLite(sin_balls[i],0.5,{delay:delay_v, scaleX:1, scaleY:1, alpha:alpha_v2, onComplete:tw_onComplete,onCompleteParams:[i]});
				flag3 *= -1;
			}
		}
		
		//animate3/OUT
		//実際のOUTでは、予め画像がならんでいるはずなのでこんなに処理はいらない、delayだけあたえれば良い
		private function animate3( e:MouseEvent = null ):void {
			
			tf.text = "SIN曲線 アニメ OUT 実行中です [" + place_no_mn[place_no] + "]";
			layer3.visible = false;
			layer4.visible = false;
			//OUT実行判定フラグ
			outflag = true;
			
			//順序切り替え
			var delay_v:Number = 0;
			var delay_total:Number = photomax * 0.5;
			var txline_mv:Number = (photomax - 1) / 2;
			var flag3:int = 1;
			//alpha
			var alpha_v2:Number = 1;
			//中外の場合加算する数値
			var d_chg_v:Number = Math.floor(Math.random() * 4 ) * 0.25;
			//alpha
			if (alpha_flag == 0 ) { alpha_v2 = 1; }
			if (alpha_flag == 1 ) { alpha_v2 = 0; }
			
			//シュミュレーションテストなので、再表示してからOUT処理している、実際は表示なっているはずである
			//OUT処理実行後、表示がなくても「OUT処理ボタン」が押されたときに、OUT処理出来るように再表示している
			var i:int = 0;
			for (i = 0; i < photomax; i++) {
				
				//中の文字位置を00にセット、回転させるため
				img_sps[i].x = 0;
				img_sps[i].y = 0;
				
				//規定の位置
				sin_balls[i].x = img_cxs[i];
				sin_balls[i].y = img_cys[i];
				//scale
				sin_balls[i].scaleX = 1;
				sin_balls[i].scaleY = 1;
				//alpha重要
				sin_balls[i].alpha = 1;
				
				//INTERPOLATE加算算用配列
				count_sin[i] = 0;//0
				
				//delay値の変化/中外4種類
				delay_v = i * 0.5;//左
				if (delay_no == 1) { delay_v = delay_total - i * 0.5; }//右
				if (delay_no == 2) { delay_v = Math.abs((i + d_chg_v) - txline_mv)*0.5; }//中
				if (delay_no == 3) { delay_v = (delay_total / 2) - Math.abs((i + d_chg_v) - txline_mv) * 0.5; }//外
				
				//遅延フラグクリア
				sin_balls[i]._chg_x = 1;
				sin_balls[i]._chg_y = 1;
				
				//遅延inversion_v/chgflag
				if (inversion_v == 1) {
					if (flag3 < 0) { delay_v += 2.25; }
				}
				//逆転inversion_v/chgflag
				if (inversion_v == 2) {
					if (flag3 < 0) {
						sin_balls[i]._chg_x = -1;
						sin_balls[i]._chg_y = -1;
					}
				}
				
				//scaleUpするか判定
				scaleUp = false;
				if (scale_v > 1) { scaleUp = true; }
				
				//グローバルカウント
				gl_count = 0;
				//TEST sin
				sin_balls[i].radian = 0;
				//振幅
				swing_y = Math.floor(Math.random() * 5) * 10 + 50;
				//中を拡大1
				img_sps[i].scaleX = 1;
				img_sps[i].scaleY = 1;
				
				//遅延させるだけが目的
				var myTween:TweenLite = new TweenLite(sin_balls[i],0.5,{delay:delay_v, scaleX:1, scaleY:1, alpha:1, onComplete:out_onComplete,onCompleteParams:[i]});
				flag3 *= -1;
			}
		}
		//再表示
		private function show_img ( e:MouseEvent = null ):void {
			tf.text = "再表示";
			var i:int = 0;
			for (i = 0; i < photomax; i++) {
				//画像列位置確定
				sin_balls[i].x = img_cxs[i];
				sin_balls[i].y = img_cys[i];
				//OUTで見えなくなっているのを補正
				sin_balls[i].alpha = 1;
				//中の拡大を修正
				img_sps[i].scaleX = 1;
				img_sps[i].scaleY = 1;
			}
		}
		
		//TweenLite-onComplete IN
		private function tw_onComplete(param1:int):void {
			//delay終了順にonEnterFrame処理を設定
			sin_balls[param1].addEventListener(Event.ENTER_FRAME, onEnterFrame_sin);
		}
		//TweenLite-onComplete OUT
		private function out_onComplete(param1:int):void {
			////delay終了順にonEnterFrame処理を設定
			sin_balls[param1].addEventListener(Event.ENTER_FRAME, onEnterFrame_sinout);
		}
		
		//ball onEnterFrame IN
		//動かすクラスは何でもballの名前をつける癖があるので、ここでもballと呼ぶ、ボールの中に画像がある
		private function onEnterFrame_sin(e:Event):void {
			//
			var count:Number = INTERPOLATE;//50
			//as Ballで問題なくコンパイル/thisは使えない
			var mv_ball:SinBall = e.currentTarget as SinBall;
			var ball_no:int = mv_ball.count_no;
			
			if (gl_count < photomax) {
				//回転rot_vをcountでわる
				mv_ball.rotation += rot_v / count;
				//mv_ball.rotation = 0;
				
				//大きいなら縮小/scaleUpするか判定
				if (img_sps[ball_no].scaleX > 1 && !scaleUp) {
					img_sps[ball_no].scaleX -= (scale_v - 1) / count;
					img_sps[ball_no].scaleY -= (scale_v - 1) / count;
				}
				//小さいなら拡大
				if (img_sps[ball_no].scaleX < 1 && scaleUp) {
					img_sps[ball_no].scaleX += (1 - scale_v) / count;
					img_sps[ball_no].scaleY += (1 - scale_v) / count;
				}
				//alpha操作するなら
				//if (alpha_flag) {
					//mv_ball.alpha += alpha_v / count;	
				//}
				//alphaが小さいなら
				if (mv_ball.alpha < 1) {
					mv_ball.alpha += alpha_v / count;
				}
					
				//最後0になるように初めに減算する(INTERPOLATE)
				//INTERPOLATE減算用配列
				count_sin[ball_no] -= 1;
				
				//保存係数
				var cx:Number =	mv_ball._chg_x;
				var cy:Number =	mv_ball._chg_y;
				
				//X方向の計算
				var by:Number = (0 * count_sin[ball_no] / count);//まだ計算なし
				var bx:Number = (ball_len_x * count_sin[ball_no] / count);
				if (no != 5) { mv_ball.x = (bx * chg_x * cx + img_cxs[ball_no]) };
				if (firstPoint == 1) { img_sps[ball_no].x = bx * chg_x * cx; }//中移動
				//螺旋X angle=3.6
				if (no == 5) {
					mv_ball.x = (Math.cos(angle5 * count_sin[ball_no] / count) * ball_len_x * count_sin[ball_no] / count) * chg_x * cx + img_cxs[ball_no];
				}
				
				//sin Y方向の計算
				mv_ball.radian += mv_ball.radian_v/count/stage.frameRate;
				if (no == 0) {
					mv_ball.y = img_cys[ball_no] + ((Math.sin(mv_ball.radian) * swing_y + by) * chg_y * cy);//外振幅プラス
				}
				if (no == 1) {
					(mv_ball.y = img_cys[ball_no] + (Math.sin(mv_ball.radian / 2) * swing_y * -1) * chg_y * cy);
				}
				if (no == 2) {
					mv_ball.y = img_cys[ball_no] +(Math.sin(mv_ball.radian / 2) * swing_y * chg_y * cy);
				}
				//bxの幅基準
				//cos Y方向の計算
				if (no == 3) {
					mv_ball.y = img_cys[ball_no] + (Math.cos(mv_ball.radian / 2) * bx * chg_y * cy);
				}
				//cos sinY/方向の計算振幅が減衰
				if (no == 4) {
					mv_ball.y = img_cys[ball_no] + ((Math.cos(mv_ball.radian / 2) - Math.sin(mv_ball.radian)) * bx * chg_y * cy);
				}
				//螺旋 angle=3.6
				if (no == 5) {
					mv_ball.y = img_cys[ball_no] + ((Math.sin(angle5 * count_sin[ball_no] / count) * ball_len_x * count_sin[ball_no] / count) * chg_y * cy);
				}
				
				//removeEventListener
				if (count_sin[ball_no] <= 0) {
					
					//グローバルカウント/反転するとカウントが正確でないのでこちらで判定
					gl_count ++;
					//回転0
					img_sps[ball_no].rotation = 0;
					mv_ball.rotation = 0;
					mv_ball.y = img_cys[ball_no];
					//スケール、アルファを戻す
					mv_ball.scaleX = 1;
					mv_ball.scaleY = 1;
					mv_ball.alpha = 1;
					
					//onEnterFrame削除、どちらでもOK
					//sin_balls[ball_no].removeEventListener(Event.ENTER_FRAME, onEnterFrame_sin);
					mv_ball.removeEventListener(Event.ENTER_FRAME, onEnterFrame_sin);
					//グローバルカウントで終了の判定、最後になったらボタン表示、終了処理に進む
					if (gl_count == photomax) { show_end(); }
				}
				
			}
		}
		
		//ball onEnterFrame OUT
		private function onEnterFrame_sinout(e:Event):void {
			//
			var count:Number = INTERPOLATE;//50
			//as Ballで問題なくコンパイル/thisは使えない
			var mv_ball:SinBall = e.currentTarget as SinBall;
			var ball_no:int = mv_ball.count_no;
			
			if (gl_count < photomax) {
				//回転rot_vをcountでわる
				mv_ball.rotation += rot_v / count;
				
				//小さいなら拡大/scaleUpするか判
				if (img_sps[ball_no].scaleX < scale_v && scaleUp) {
					img_sps[ball_no].scaleX += (scale_v - 1) / count;
					img_sps[ball_no].scaleY += (scale_v - 1) / count;
				}
				//大きいなら縮小
				if (img_sps[ball_no].scaleX > scale_v && !scaleUp) {
					img_sps[ball_no].scaleX -= (1 - scale_v) / count;
					img_sps[ball_no].scaleY -= (1 - scale_v) / count;
				}
				//alpha操作するなら
				if (alpha_flag) {
					mv_ball.alpha -= alpha_v / count;
				}
				
				//INTERPOLATE加算用配列
				count_sin[ball_no] += 1;
				
				//保存係数
				var cx:Number =	mv_ball._chg_x;
				var cy:Number =	mv_ball._chg_y;
				
				//X方向の計算
				var by:Number = (0 * count_sin[ball_no] / count);//まだ計算なし
				var bx:Number = (ball_len_x * count_sin[ball_no] / count);
				if (no != 5) {mv_ball.x = (bx * chg_x * cx + img_cxs[ball_no])};
				if (firstPoint == 1) { img_sps[ball_no].x = bx * chg_x * cx; }//中移動
				//螺旋X angle=3.6
				if (no == 5) {
					mv_ball.x = (Math.cos(angle5 * count_sin[ball_no] / count) * ball_len_x * count_sin[ball_no] / count) * chg_x * cx + img_cxs[ball_no];
				}
				
				//sin Y方向の計算
				mv_ball.radian += mv_ball.radian_v/count/stage.frameRate;
				if (no == 0) {
					mv_ball.y = img_cys[ball_no] + ((Math.sin(mv_ball.radian) * swing_y + by) * chg_y * cy);//外振幅プラス
				}
				if (no == 1) {
					(mv_ball.y = img_cys[ball_no] + (Math.sin(mv_ball.radian / 2) * swing_y * -1) * chg_y * cy);
				}
				if (no == 2) {
					mv_ball.y = img_cys[ball_no] + (Math.sin(mv_ball.radian / 2) * swing_y * chg_y * cy);
				}
				//bxの幅基準
				//cos Y方向の計算
				if (no == 3) {
					mv_ball.y = img_cys[ball_no] + (Math.cos(mv_ball.radian / 2) * bx * chg_y * cy);
				}
				//cos sinY/方向の計算振幅が減衰
				if (no == 4) {
					mv_ball.y = img_cys[ball_no] + ((Math.cos(mv_ball.radian / 2) - Math.sin(mv_ball.radian)) * bx * chg_y * cy);
				}
				//螺旋 angle=3.6
				if (no == 5) {
					mv_ball.y = img_cys[ball_no] + ((Math.sin(angle5 * count_sin[ball_no] / count) * ball_len_x * count_sin[ball_no] / count) * chg_y * cy);
				}
				
				//removeEventListener
				if (count_sin[ball_no] >= INTERPOLATE) {
					
					//文字の場合は重要だが、画像だからalpha=0はOK、visibleで操作しても良い
					mv_ball.alpha = 0;
					//グローバルカウント/反転するとカウントが正確でないのでこちらで判定
					gl_count ++;
					//回転0
					img_sps[ball_no].rotation = 0;
					mv_ball.rotation = 0;
					mv_ball.y = 0;
					//OUTだけの場合拡大のままだと影響があるので中も戻す
					img_sps[ball_no].scaleX = 1;
					img_sps[ball_no].scaleY = 1;
					//scaleを戻す
					mv_ball.scaleX = 1;
					mv_ball.scaleY = 1;
					//onEnterFrame削除
					mv_ball.removeEventListener(Event.ENTER_FRAME, onEnterFrame_sinout);
					//グローバルカウントで終了の判定、最後になったらボタン表示、終了処理に進む
					if (gl_count == photomax) { show_end(); }
				}
				
			}
		}
		
		//終了処理、ボタン表示する。作動中にボタンを押すと崩れるので非表示にしている
		private function show_end ():void {
			//グローバルカウントクリア
			gl_count = 0;
			//レーヤー表示
			layer3.visible = true;
			layer4.visible = true;
			tf.text = "SIN曲線 移動完了 ドラッグポイント x:" + container.x + " y:" + container.y;
		}
		
		//簡易ドラッグ設定/注意Sprite容器でなければ機能しない
		private function onFileMouseDown(event:MouseEvent):void {
			event.currentTarget.startDrag();
		}
		private function onFileMouseUp(event:MouseEvent):void {
			event.currentTarget.stopDrag();
			tf.text = "x:" + container.x + " y:" + container.y;
		}

		//ERROR
		private function ioErrorHandler(event:IOErrorEvent):void {
			//ERROR処理
			tf.text = "LOADING-EROOR";
			
			//画像ERRORならカウントをすすめて次ぎ画像ロードに進む
			countImage ++;
			loadImage();
		}
		//LOADING回転
		private function step(evt:Event):void {
			indicator.rotation = (indicator.rotation + 360 / stage.frameRate) % 360;
		}

		//create-box
		private function createSquare(x:Number, y:Number, width:Number, height:Number, color:Number, alpha:Number):Sprite {
			var s:Sprite = new Sprite();
			s.graphics.beginFill(color, alpha);
			s.graphics.drawRect(x, y, width, height);
			s.graphics.endFill();
			//addChild(s);
			return s;
		}
		//create-text
		private function createTextField(x:Number, y:Number, width:Number, height:Number):TextField {
			var result:TextField = new TextField();
			result.x = x;
			result.y = y;
			result.width = width;
			result.height = height;
			//addChild(result);
			return result;
		}
		//create-RoundBTN/原点中央ボタンモードなど訂正
		private function createRoundBTN(text:String, t_size:int, t_color:uint, width:Number, height:Number, color:uint, alpha:Number, round:Number):Sprite {
			var rsbt:Sprite = new Sprite();
			rsbt.graphics.beginFill(color, alpha);
			rsbt.graphics.drawRoundRect(-width/2, -height/2, width, height, round);
			rsbt.graphics.endFill();
			addChild(rsbt);
			var r:TextField = new TextField();
			var fmt:TextFormat = new TextFormat('_ゴシック', t_size, null, null, null, null, null, null, TextFormatAlign.CENTER );
			r.defaultTextFormat = fmt;
			r.textColor = t_color;
			r.selectable = false;
			//r.autoSize = TextFieldAutoSize.LEFT;
			r.text = text;
			r.width = width;
			r.height = height;
			r.x = -width / 2;
			r.y = -height / 2 + 2;
			r.mouseEnabled = false;
			//buttonMode
			rsbt.buttonMode = true;
			rsbt.addChild(r);
			return rsbt;
		}
	}
}

//RoundBtnクラス/原点中央ボタンモードなど訂正
import flash.display.*;
import flash.utils.*;
import flash.text.*;
class RoundBtn extends Sprite {
	//
	public function RoundBtn(text:String, t_size:int, t_color:uint, width:Number, height:Number, color:uint, alpha:Number, round:Number):void {
			var rsbt:Sprite = new Sprite();
			rsbt.graphics.beginFill(color, alpha);
			rsbt.graphics.drawRoundRect(-width/2, -height/2, width, height, round);
			rsbt.graphics.endFill();
			addChild(rsbt);
			var r:TextField = new TextField();
			var fmt:TextFormat = new TextFormat('_ゴシック', t_size, null, null, null, null, null, null, TextFormatAlign.CENTER );
			r.defaultTextFormat = fmt;
			r.textColor = t_color;
			r.selectable = false;
			//r.autoSize = TextFieldAutoSize.LEFT;
			r.text = text;
			r.width = width;
			r.height = height;
			r.x = -width / 2;
			r.y = -height / 2 + 2;
			r.mouseEnabled = false;
			//buttonMode
			rsbt.buttonMode = true;
			rsbt.addChild(r);
	}
}

//SinBall運動クラス、文字のものをそのまま使用
//onEnterFrame処理の、個別の判定などに利用、ここに直接onEnterFrameを書いても良いのだが
import flash.display.*;
class SinBall extends Sprite {
	//番号
	public var count_no:Number;
	//回転方向 0=左 1=右
	public var direction:int;
	//逆転係数
	public var chgFlag:Number = 1;
	//逆転係数2
	public var _chg_x:Number = 1;
	public var _chg_y:Number = 1;
	//TEST
	public var radian:Number = 0;
	public var radian_v:Number = 180;
	//未使用
	private var _x:Number = 0;
	private var _y:Number = 0;

	public function SinBall() {
		var b:Sprite = new Sprite();
		//xy
		b.x = 0;
		b.y = 0;
		addChild(b);
	}
}

//LOADING-Shape
import flash.display.Shape;
class Indicator extends Shape {
	public function Indicator(){
		var i:uint,
		cx:Number, cy:Number,
		numNeedles:uint = 12,
		innerR:Number = 7,
		outerR:Number = 5,
		cAngle:Number = -Math.PI / 2,
		nAngle:Number;
		nAngle = Math.PI * 2 / numNeedles;
		for (i=0; i<numNeedles; i++){
			cAngle += nAngle;
			cx = Math.cos(cAngle) * innerR;
			cy = Math.sin(cAngle) * innerR;
			graphics.moveTo(cx, cy);
			cx = Math.cos(cAngle) * outerR;
			cy = Math.sin(cAngle) * outerR;
			graphics.lineStyle(2, 0xffffff, i/numNeedles);
			graphics.lineTo(cx, cy);
		}
	}
}

使用画像

1 画像80x60 2 3 4 5

以上のように、曲線で動かすのは大変です。普通に直線で、Tweenさせた方が簡単です。ライブラリを使用する手段もありますが、、。
少したちましたらボタンなど削除して、簡易形にしたものを書きます。


サイン曲線と文字の運動、シュミュレーションテスト

【参考】シュミュレーションテスト: 文字を分解してアニメ処理で表示9


以上です。



[ この記事のURL ]


タグ:series , as3 , ActionScript , flash

[ サイン曲線で画像を動かすテストです シリーズ記事 ]

サイン曲線で画像を動かすテストです/32012.04.24
サイン曲線で画像を動かすテストです/22012.04.22
サイン曲線で画像を動かすテストです/12012.04.21

 

ブログ記事一覧

年別アーカイブ一覧



[1]