POPSブログ

三次ベジェ曲線で文字を動かす/3

89

  Category:  as32012/04/20 pops 

三次ベジェ曲線を使用した画像運動表示をさせてみました。画像運動シュミュレーション(simulation)表示。


三次ベジェ曲線と画像の運動との関係

三次ベジェ曲線を使用した文字運動とほぼ同じようなものです。文字より画像のほうがマッチするようです。文字はsin曲線を利用したほうが利便性があるようです。


三次ベジェ曲線曲線を使用した運動のシュミュレーションテスト3

条件を変えて実行してください。(「指定位置」の場合「交互遅延」は機能しません)


注意、FlashTest187c.swf、は画像を読み込んでいるため、当方専用になります。/main/images/xxx.jpg


簡単な動作の説明

説明図


1.3次ベジェ曲線関数により、右より左に移動しているだけです。
2.ベジェ曲線の種類を指定できます。現在0-5番まで6種類あります。
3.Y軸およびX軸で反転させて、方向を違わせています。ここでは位相の切り替えと呼んでいます。
4.位置の指定ができます。指定位置からの場合ラインが変形します。
5.アニメ処理はdelay値を変えるためのみ使用され、ベジェ曲線運動はonEnterFrameで処理します。delay値をもっとかえれば拠り複雑な動きになります。
6.運動用のSpriteの中に画像を流し込み、onEnterFrame処理しています。パーテクルのようなものです。
7.注意、文字の場合と構造が少し違います。「画像専用」になりますので文字用には転用できません。


このコードはシュミュレーション用ですのでボタン類が多く判りにくいと思います。次ぎのページに「コードを簡略化」したものを掲載します。


AS3

FlashTest187c.as


//動く画像表示テスト
//FlashTest187c
//三次ベジェ曲線
//
package
{
	
	import flash.display.*;
	import flash.events.*;
	import flash.net.*;
	import flash.geom.*;
	import flash.system.*;
	import flash.utils.*;
	import flash.text.*;
	import flash.filters.DropShadowFilter;
	
	//TweenLite
	import com.greensock.*;
	import com.greensock.easing.*;
	
	[SWF(width="465", height="465", frameRate="30", backgroundColor="0xFFFFFF")]

	public class FlashTest187c extends Sprite {
		
		//補間数(高いほど綺麗で重い)
		static public const	INTERPOLATE:Number = 50;
		private var d:Number = 0;// 係数
		private var plus:Number = 0.01;// 加算量
		//layer container
		private var layer1:Sprite;
		private var layer3:Sprite;
		private var layer4:Sprite;
		private var layer5:Sprite;
		private var backlayer:Sprite;
		private var container:Sprite;
		//TEXT
		private var txfcolor:uint = 0x6496ED;
		private var tf:TextField;
		private var tf2:TextField;
		private var tf3:TextField;
		private var tf4:TextField;
		private var tf5:TextField;
		private var tf6:TextField;
		private var tf7:TextField;
		//BTN
		private var btn_1:Sprite;
		private var btn_2:Sprite;
		private var btn_3:Sprite;
		private var btn_4:Sprite;
		private var btn_5:Sprite;
		private var btn_6:Sprite;
		private var btn_7:Sprite;
		private var btn_8:Sprite;
		//画像指定pointer位置
		private var pointer:Sprite;
		private var pointer_x:Number = 420;
		private var pointer_y:Number = 100;
		
		//MOVE-IMAGE
		private var photomax:int;
		//格納容器1
		private var bez_balls:Array = [];//要素bez_ball格納容器
		private var count_bez:Array = [];//INTERPOLATE減算用配列
		
		//ベジェ曲線
		private var p0:Object;
		private var p1:Object;
		private var p2:Object;
		private var p3:Object;
		private var first_points:Array = [];//同一地点オブジェクト格納容器
		//距離/350以外は波形がかわる
		private var ball_len_x:Number = 350;//350使用
		private var ball_len_y:Number = 350;//350未使用
		
		//個別に初期位置を同一にする/1=強制移動 0=移動しない
		private var firstPoint:int = 0;
		private var txs:Array = new Array('初期位置','指定位置');
		private var no:int = 0;
		private var rotatno:int = 0;
		private var rot:Array = [0, 360, -360, 180, -180];
		private var rot_v:Number = 0;//回転数
		//逆転係数
		private var chg_x:Number = 1;
		private var chg_y:Number = 1;
		private var chg_xyno:Number = 0;
		//順序切り替え
		private var delay_no:int = 0;
		private var delay_nm:Array = new Array('左', '右', '中', '外');
		//遅延反転
		private var inversion_v:int = 0;
		private var inversion_nm:Array = new Array('通常動作', '交互遅延', '交互反転');
		//グローバルカウント
		private var gl_count:int = 0;
		//背景番号
		private var back_no:int = 0;
		private var backcolors:Array = new Array(0x000000,0xFFFFFF,0xF0F0F0,0xE6DDD6,0xA3BACD,0x808080);
		//LOADER
		private var loader:Loader;
		//Loading
		private var indicator:DisplayObject;
		//現在表示画像配列番号
		private var countImage:int = 0;
		//画像Bitmap
		private var mainImages:Array = [];//Array-Bitmap
		//画像のおおきさ
		private var image_W:Number = 80;
		private var image_H:Number = 60;
		//画像収容Sprite
		private var mainImageBox:Sprite;
		//URL
		private var imageUrls:Array = [];
		//画像位置保存用	
		private var _arrX:Array = [];//X位置保存
		private var _arrY:Array = [];//Y位置保存
		private var _arrW:Array = [];//幅保存
		private var _arrH:Array = [];//高さ保存
		//Filter
		private var shade:DropShadowFilter;
		
		public function FlashTest187c():void {
			
			//回転数
			rot_v = rot[rotatno];
			
			//BASE/黒背景
			graphics.beginFill(0xB0C4DE);//0x000000
			graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
			graphics.endFill();
			
			//白背景レーヤー
			backlayer = createSquare(0, 0, stage.stageWidth, stage.stageHeight, 0x000000, 1);
			addChild(backlayer);
			
			//layer1 文字関係をまとめた
			layer1 = new Sprite();
			addChild(layer1);
			//text
			tf = createTextField(10, 445, 400, 20);
			tf.textColor = txfcolor;
			tf.text = "";
			tf.selectable = false;
			layer1.addChild(tf);
			
			//BTN-8
			btn_8 = createRoundBTN("背景切替", 13, 0x000000, 60, 20, 0xAAAAAA, 1, 5);
			btn_8.x = 430;
			btn_8.y = 445;
			layer1.addChild(btn_8);
			
			//ボタンレーヤー
			layer3 = new Sprite();
			addChild(layer3);
			//BTN-7
			btn_7 = createRoundBTN("遅延反転", 13, 0x000000, 60, 20, 0xAAAAAA, 1, 5);
			btn_7.x = 40;
			btn_7.y = 15;
			layer3.addChild(btn_7);
			//BTN-6
			btn_6 = createRoundBTN("順序切替", 13, 0x000000, 60, 20, 0xAAAAAA, 1, 5);
			btn_6.x = 110;
			btn_6.y = 15;
			layer3.addChild(btn_6);
			//BTN-5
			btn_5 = createRoundBTN("位相切替", 13, 0x000000, 60, 20, 0xAAAAAA, 1, 5);
			btn_5.x = 180;
			btn_5.y = 15;
			layer3.addChild(btn_5);
			//BTN-4
			btn_4 = createRoundBTN("回転切替", 13, 0x000000, 60, 20, 0xAAAAAA, 1, 5);
			btn_4.x = 250;
			btn_4.y = 15;
			layer3.addChild(btn_4);
			//BTN-3
			btn_3 = createRoundBTN("番号切替", 13, 0x000000, 60, 20, 0xAAAAAA, 1, 5);
			btn_3.x = 320;
			btn_3.y = 15;
			layer3.addChild(btn_3);
			//BTN-2
			btn_2 = createRoundBTN("位置切替", 13, 0x000000, 60, 20, 0xAAAAAA, 1, 5);
			btn_2.x = 390;
			btn_2.y = 15;
			layer3.addChild(btn_2);
			//BTN-1
			btn_1 = createRoundBTN("アニメ", 13, 0x000000, 30, 20, 0xFF69B4, 1, 5);
			btn_1.x = 440;
			btn_1.y = 15;
			layer3.addChild(btn_1);
			layer3.visible = false;
			
			//TEXTレーヤー
			layer5 = new Sprite();
			addChild(layer5);
			//text7
			tf7 = createTextField(10, 30, 60, 20);
			tf7.textColor = txfcolor;
			tf7.text = "通常動作";
			layer5.addChild(tf7);
			//text6
			tf6 = createTextField(80, 30, 60, 20);
			tf6.textColor = txfcolor;
			tf6.text = "左";
			layer5.addChild(tf6);
			//text5
			tf5 = createTextField(150, 30, 60, 20);
			tf5.textColor = txfcolor;
			tf5.text = "位相 0";
			layer5.addChild(tf5);
			//text4
			tf4 = createTextField(220, 30, 60, 20);
			tf4.textColor = txfcolor;
			tf4.text = "回転 0";
			layer5.addChild(tf4);
			//text3
			tf3 = createTextField(290, 30, 60, 20);
			tf3.textColor = txfcolor;
			tf3.text = "番号 0";
			layer5.addChild(tf3);
			//text2
			tf2 = createTextField(360, 30, 60, 20);
			tf2.textColor = txfcolor;
			tf2.text = "初期位置";
			layer5.addChild(tf2);
			
			//MOVE文字containerレーヤー
			container = createSquare(0, 0, stage.stageWidth, 1, 0xEEEEEE, 0);
			container.x = 12;//5
			container.y = 300;
			addChild(container);
						
			//LOADING
			indicator = new Indicator();
			indicator.x = 12;
			indicator.y = 15;
			indicator.addEventListener(Event.ENTER_FRAME, step);//回転Listener
			addChild(indicator);
			indicator.visible = false;
			
			//goto-init
			init();
		}
		
		// INIT
		private function init():void {
			
			//5画像指定位置
			pointer = new MarkerBall(4, 0x8865B2) as Sprite;
			pointer.x = pointer_x;
			pointer.y = pointer_y;
			addChild(pointer);
			//drag-Listener
			pointer.addEventListener(MouseEvent.MOUSE_DOWN, onFileMouseDown);
			pointer.addEventListener(MouseEvent.MOUSE_UP, onFileMouseUp);
			//drag-Listener2
			container.addEventListener(MouseEvent.MOUSE_DOWN, onBoxMouseDown);
			container.addEventListener(MouseEvent.MOUSE_UP, onBoxMouseUp);
			
			//goto-main
			main_action();
		}
		
		// MAIN-ACTION
		private function main_action():void {
			//main_action as3 hear
			tf.text = "三次ベジェ曲線 ドラッグで移動可能です";
			//url取得、画像読み込みに進む
			loadImage_Url_Set();
		}
		
		// 画像URL-SET
		private function loadImage_Url_Set():void {
			//画像URL 80x60
			imageUrls = [
				"/main/images/photo_bz1.jpg",
				"/main/images/photo_bz2.jpg",
				"/main/images/photo_bz3.jpg",
				"/main/images/photo_bz4.jpg",
				"/main/images/photo_bz5.jpg"
			];
			
			//カウント
			countImage = 0;
			//画像数
			photomax = imageUrls.length;
			//LOADING表示
			indicator.visible = true;
			//GOTO-loadImage
			loadImage();
		}
		// 画像をロード
		private function loadImage():void
		{
			//loaderを構成
			loader = new Loader();
			var imageName:String = imageUrls[countImage];
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete_img);//
			loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);//Error
			loader.load(new URLRequest(imageName));//loader
		}

		private function onComplete_img(event:Event):void {
			loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, onComplete_img);
			tf.text = "画像読み込み中";
			
			//main-imageの加工保存
			//Matrixを使用した場合
			var mainloader:Loader = event.currentTarget.loader;
			var ratio:Number = image_W / loader.width;//縮尺比率
			var matrix:Matrix = new Matrix();
			matrix.scale(ratio, ratio);
			var bd2:BitmapData = new BitmapData(image_W, image_H, false);
			bd2.draw(mainloader, matrix);//Matrixを適応
			mainImages.push(bd2);
			
			//画像大きさ受け渡し
			_arrW.push(event.target.content.width);
			_arrH.push(event.target.content.height);
			
			countImage ++;
			
			//全て読み込んだらinitにまだなら残り画像をロードする
			if (countImage >= photomax) {
				//LOADING非表示
				indicator.visible = false;
				//画像をロード終了
				make_ImageBox();
				
			} else {
				//残り画像をLoad
				loadImage();
			}
			
		}
		
		//画像の要素を作る
		private function make_ImageBox():void {
			//max再計算
			photomax = mainImages.length;
			//Filter
			shade = new DropShadowFilter(1, 90, 0x000000, 0.4, 4, 4, 2, 3, false, false);
			var allpoint:Number = 0;
			var i:int = 0;
			for (i = 0; i < photomax; i++) {
				
				//BezImgBallクラス生成
				//画像の場合は直接BitmapDataを流し込むほうが簡単だ、中にSpriteをaddChildすると中心補正が難しい
				var ball:BezImgBall = new BezImgBall(mainImages[i], _arrW[i], _arrH[i]);
				//識別番号をいれる
				ball.count_no = i;
				ball.filters = [shade];
				bez_balls[i] = ball;
				//X位置を決める
				allpoint += _arrW[i]/2;
				_arrX[i] = allpoint;
				_arrY[i] = 0;//Yは0
				//画像間の隙間をプラス
				allpoint += (_arrW[i]/2 + 10);
				container.addChild(ball);
			}
			
			//btn_1にListenerを設定
			btn_1.addEventListener( MouseEvent.CLICK, show_image );
			//btn_2にListenerを設定
			btn_2.addEventListener( MouseEvent.CLICK, setpoint_chg );
			//btn_3にListenerを設定
			btn_3.addEventListener( MouseEvent.CLICK, number_chg );
			//btn_4にListenerを設定
			btn_4.addEventListener( MouseEvent.CLICK, rotat_chg );
			//btn_5にListenerを設定
			btn_5.addEventListener( MouseEvent.CLICK, xy_chg );
			//btn_6にListenerを設定
			btn_6.addEventListener( MouseEvent.CLICK, delay_chg );
			//btn_7にListenerを設定
			btn_7.addEventListener( MouseEvent.CLICK, inversion_chg );
			//btn_8にListenerを設定
			btn_8.addEventListener( MouseEvent.CLICK, back_chg );
			
			//GOTO-animate
			show_image();
			
		}
		
		//背景切り替え
		private function back_chg(e:MouseEvent):void {
			back_no ++;
			if (back_no > 5 ) { back_no = 0; }
			back_colorchg(backcolors[back_no]);
		}
		//反転遅延
		private function inversion_chg(e:MouseEvent):void {
			inversion_v ++;
			if (inversion_v > 2) { inversion_v = 0; }
			tf7.text = "" + inversion_nm[inversion_v];
		}
		//順序切り替え
		private function delay_chg(e:MouseEvent):void {
			delay_no ++;
			if (delay_no > 3) { delay_no = 0; }
			tf6.text = "" + delay_nm[delay_no];
		}
		//位相切り替え
		private function xy_chg(e:MouseEvent):void {
			chg_xyno ++;
			if (chg_xyno > 3) { chg_xyno = 0; }
			//位相切り替え
			if (chg_xyno == 0) { chg_x = 1; chg_y = 1; }
			if (chg_xyno == 1) { chg_x = 1; chg_y = -1; }
			if (chg_xyno == 2) { chg_x = -1; chg_y = 1; }
			if (chg_xyno == 3) { chg_x = -1; chg_y = -1; }
			tf5.text = "" + chg_xyno;
		}
		//回転切り替え
		private function rotat_chg(e:MouseEvent):void {
			//0 360 -360 180 -180
			rotatno ++;
			if (rotatno > 4 ) { rotatno = 0; }
			rot_v = rot[rotatno];
			tf4.text = "" + rot_v;
		}
		//番号切り替え
		private function number_chg(e:MouseEvent):void {
			//0-5
			no ++;
			if (no > 5 ) { no = 0; }
			tf3.text = "" + no;
		}
		//初期位置切り替え
		private function setpoint_chg(e:MouseEvent):void {
			//
			firstPoint ++;
			if (firstPoint > 1) { firstPoint = 0; }
			//if (firstPoint == 1) { firstPoint = 0; } else { firstPoint = 1; }
			tf2.text = "" + txs[firstPoint];
		}
		private function back_colorchg(bcolor:uint):void {
			backlayer.graphics.clear();
			backlayer.graphics.beginFill(bcolor);//0x000000
			backlayer.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
			backlayer.graphics.endFill();
		}
		
		//animate show-image
		private function show_image( e:MouseEvent = null ):void {
			
			//ボタン非表示/アニメ途中おされるとくるう
			layer3.visible = false;
			
			//no = Math.random() * 6;
			tf.text = "三次ベジェ曲線 アニメ実行中";
			//指定位置の場合反転させない
			if (firstPoint && inversion_v == 2) { tf7.text = "---";}
			
			var p0_v:Object;
			var p1_v:Object;
			var p2_v:Object;
			var p3_v:Object;
			
			//ベジェ曲線サンプル波形 x350
			switch (no) {
				case 0:
					p0_v = {x:0,y:0};
					p1_v = {x:30,y:-150};
					p2_v = {x:320,y:-150};
					p3_v = {x:ball_len_x, y:0};
				break;
				case 1:
					p0_v = {x:0,y:0};
					p1_v = {x:130,y:-80};
					p2_v = {x:220,y:-80};
					p3_v = {x:ball_len_x,y:0};
				break;
				case 2:
					p0_v = {x:0,y:0};
					p1_v = {x:-130,y:-150};
					p2_v = {x:220,y:-80};
					p3_v = {x:ball_len_x,y:0};
				break;
				case 3:
					p0_v = {x:0,y:0};
					p1_v = {x:150,y:-180};
					p2_v = {x:200,y:180};
					p3_v = {x:350,y:0};
				break;
				case 4:
					p0_v = {x:0,y:0};
					p1_v = {x:0,y:150};
					p2_v = {x:130,y:220};
					p3_v = {x:ball_len_x,y:0};
				break;
				case 5:
					p0_v = {x:0,y:0};
					p1_v = {x:130,y:50};
					p2_v = {x:0,y:-250};
					p3_v = {x:ball_len_x,y:0};
				break;
				default:
					//ノーマル
					p0_v = {x:0,y:0};
					p1_v = {x:30,y:-150};
					p2_v = {x:320,y:-150};
					p3_v = {x:ball_len_x, y:0};
			}
			
			//位相切り替え
			p0_v.x *=chg_x;
			p0_v.y *=chg_y;
			p1_v.x *=chg_x;
			p1_v.y *=chg_y;
			p2_v.x *=chg_x;
			p2_v.y *=chg_y;
			p3_v.x *=chg_x;
			p3_v.y *=chg_y;

			//出現位置を文字初期位置に強制移動
			if (firstPoint) {
				p3_v = { x:pointer.x - container.x, y:pointer.y - container.y };
			}
			
			//グローバルに代入
			p0 = p0_v, p1 = p1_v, p2 = p2_v, p3 = p3_v;
			
			//順序切り替え
			var delay_v:Number = 0;
			var delay_total:Number = photomax * 0.5;
			var txline_mv:Number = (photomax - 1) / 2;
			//中外の場合加算する数値
			var d_chg_v:Number = Math.floor(Math.random() * 4 ) * 0.25;
			var flag3:int = 1;
			
			var i:int = 0;
			for (i = 0; i < photomax; i++) {
				
				//同一地点オブジェクト格納容器に要素ごとの初期位置を代入
				if (firstPoint) {
					first_points[i] = { x:pointer.x - container.x - _arrX[i], y:pointer.y - container.y - _arrY[i] }
				}
				//初期位置、ポインターにあわせる/1番目の位置、そのほかは実際右にある
				if (firstPoint) {
					bez_balls[i].x = pointer.x - container.x;
					bez_balls[i].y = pointer.y - container.y;
				}
				else {
					//見えない場用に移動/位相補正
					bez_balls[i].x = (stage.stageWidth + 200)*chg_x;
					bez_balls[i].y = container.y;
				}
				
				//scale/文字ではないので0でもOK
				bez_balls[i].scaleX = 0.1;
				bez_balls[i].scaleY = 0.1;
				
				//INTERPOLATE減算用配列
				count_bez[i] = INTERPOLATE;//50
				
				//delay値の変化/中外4種類
				delay_v = i * 0.5;//左
				if (delay_no == 1) { delay_v = delay_total - i * 0.5; }//右
				if (delay_no == 2) { delay_v = Math.abs((i + d_chg_v) - txline_mv)*0.5; }//中
				if (delay_no == 3) { delay_v = (delay_total / 2) - Math.abs((i + d_chg_v) - txline_mv) * 0.5; }//外
				
				//遅延フラグクリア
				bez_balls[i]._chg_x = 1;
				bez_balls[i]._chg_y = 1;
				
				//遅延inversion_v/chgflag
				if (inversion_v == 1) {
					if (flag3 < 0) { delay_v += 2.25; }
				}
				//逆転inversion_v/chgflag
				if (inversion_v == 2) {
					if (flag3 < 0) {
						bez_balls[i]._chg_x = -1;
						bez_balls[i]._chg_y = -1;
					}
				}
				
				//グローバルカウント
				gl_count = 0;
				
				//遅延させるTweenLite
				var myTween:TweenLite = new TweenLite(bez_balls[i],0.5,{delay:delay_v, scaleX:1, scaleY:1, onComplete:tw_onComplete,onCompleteParams:[i]});
				flag3 *= -1;
			}
		}
		//TweenLite-onComplete
		private function tw_onComplete(param1:int):void {
			//onEnterFrame処理
			bez_balls[param1].addEventListener(Event.ENTER_FRAME, onEnterFrame_bez);
		}
		
		//ball onEnterFrame
		private function onEnterFrame_bez(e:Event):void {
			//
			var count:Number = INTERPOLATE;//50
			//as Ballで問題なくコンパイル
			var mv_ball:BezImgBall = e.currentTarget as BezImgBall;
			var ball_no:int = mv_ball.count_no;
			
			if (gl_count < photomax) {
				//回転rot_vをcountでわる
				mv_ball.rotation += rot_v / count;
				
				//最後0になるように初めに減算する(INTERPOLATE)
				//INTERPOLATE減算用配列
				count_bez[ball_no] -= 1;
				
				var dd:Number = count_bez[ball_no] / count;
				if (dd > 1) { dd = 1; }//強制的に1にする
				if (dd < 0) { dd = 0; }//最後0にする
				
				//個別に初期位置を同一にする
				if (firstPoint) {
					p3 = first_points[ball_no];
				}
				
				//保存係数/位相反転
				var cx:Number = mv_ball._chg_x;
				var cy:Number = mv_ball._chg_y;
				//指定位置の場合反転させない
				if (firstPoint) { cx = cy = 1;}
				
				//今回の座標
				var pos:Object = CubicBezPoint( p0, p1, p2, p3, dd);
				mv_ball.x = pos.x * cx + _arrX[ball_no];
				mv_ball.y = pos.y * cy + _arrY[ball_no];
				//removeEventListener
				if (count_bez[ball_no] <= 0) {
					
					//グローバルカウント/反転するとカウントが正確でないのでこちらで判定
					gl_count ++;
					//回転0
					mv_ball.rotation = 0;
					bez_balls[ball_no].removeEventListener(Event.ENTER_FRAME, onEnterFrame_bez);
					//最後になったら終了処理に
					if (gl_count == photomax) { show_end(); }
				}
				
			}
		}

		//終了処理
		//ボタン表示作動中にボタンを押すと崩れるので非表示にしている
		private function show_end ():void {
			gl_count = 0;
			layer3.visible = true;
			tf.text = "三次ベジェ曲線 アニメ終了 x:" + container.x + " y:" + container.y;
		}
		
		/* --------------------------------------
		3次ベジェ曲線上の1点を取得する
		第01引数	頂点データ1(開始)
		第02引数	頂点データ2(制御1)
		第03引数	頂点データ3(制御2)
		第04引数	頂点データ4(終了)
		第05引数	係数(0 ~ 1)
		-------------------------------------- */
		private function CubicBezPoint( p0:Object, p1:Object, p2:Object, p3:Object, d:Number):Object {
			
			var o:Object = {x:0,y:0};
			var tmp:Number = (1 - d) * (1 - d) * (1 - d);
			
			o.x += tmp * p0.x;	
			o.y += tmp * p0.y;
			
			tmp = 3 * d * (1-d) * (1-d);
			o.x += tmp * p1.x;
			o.y += tmp * p1.y;
			
			tmp = 3 * d * d * (1-d);
			o.x += tmp * p2.x;
			o.y += tmp * p2.y;
			
			tmp = d * d * d;
			o.x += tmp * p3.x;
			o.y += tmp * p3.y;
			
			return o;
		}

		//ポインターに簡易ドラッグ設定/注意Sprite容器でなければ機能しない
		private function onFileMouseDown(event:MouseEvent):void {
			event.currentTarget.startDrag();
		}
		private function onFileMouseUp(event:MouseEvent):void {
			event.currentTarget.stopDrag();
		}
		
		//画像コンテナに簡易ドラッグ設定
		private function onBoxMouseDown(event:MouseEvent):void {
			event.currentTarget.startDrag();
		}
		private function onBoxMouseUp(event:MouseEvent):void {
			event.currentTarget.stopDrag();
			tf.text = "x:" + container.x + " y:" + container.y;
		}
		
		//ERROR
		private function ioErrorHandler(event:IOErrorEvent):void {
			//ERROR処理
			tf.text = "LOADING-EROOR";
			
			//画像ERRORならカウントをすすめて次ぎ画像ロードに進む
			countImage ++;
			loadImage();
		}
		//LOADING回転
		private function step(evt:Event):void {
			indicator.rotation = (indicator.rotation + 360 / stage.frameRate) % 360;
		}
		
		//create-box
		private function createSquare(x:Number, y:Number, width:Number, height:Number, color:Number, alpha:Number):Sprite {
			var s:Sprite = new Sprite();
			s.graphics.beginFill(color, alpha);
			s.graphics.drawRect(x, y, width, height);
			s.graphics.endFill();
			//addChild(s);
			return s;
		}
		//create-Roundbox
		private function createSquare2(x:Number, y:Number, width:Number, height:Number, color:Number, alpha:Number, round:Number):Sprite {
			var rs:Sprite = new Sprite();
			rs.graphics.beginFill(color, alpha);
			rs.graphics.drawRoundRect(x, y, width, height, round);
			rs.graphics.endFill();
			//addChild(rs);
			return rs;
		}
		//create-text
		private function createTextField(x:Number, y:Number, width:Number, height:Number):TextField {
			var result:TextField = new TextField();
			result.x = x;
			result.y = y;
			result.width = width;
			result.height = height;
			//addChild(result);
			return result;
		}
		//create-RoundBTN/原点中央ボタンモードなど訂正
		private function createRoundBTN(text:String, t_size:int, t_color:uint, width:Number, height:Number, color:uint, alpha:Number, round:Number):Sprite {
			var rsbt:Sprite = new Sprite();
			rsbt.graphics.beginFill(color, alpha);
			rsbt.graphics.drawRoundRect(-width/2, -height/2, width, height, round);
			rsbt.graphics.endFill();
			addChild(rsbt);
			var r:TextField = new TextField();
			var fmt:TextFormat = new TextFormat('_ゴシック', t_size, null, null, null, null, null, null, TextFormatAlign.CENTER );
			r.defaultTextFormat = fmt;
			r.textColor = t_color;
			r.selectable = false;
			//r.autoSize = TextFieldAutoSize.LEFT;
			r.text = text;
			r.width = width;
			r.height = height;
			r.x = -width / 2;
			r.y = -height / 2 + 2;
			r.mouseEnabled = false;
			//buttonMode
			rsbt.buttonMode = true;
			rsbt.addChild(r);
			return rsbt;
		}
		
	}
}

//MarkerBallクラス
import flash.display.Sprite;
class MarkerBall extends Sprite {
	//
	private var _color:uint;
	private var _radius:Number;	
	//未使用
	private var _x:Number = 0;
	private var _y:Number = 0;

	public function MarkerBall(radius:Number = 5, color:uint = 0xFF0000) {
		
		_color = color;
		_radius = radius;
		
		var b:Sprite = new Sprite();
		//xy
		b.x = 0;
		b.y = 0;
		//円の描画
		b.graphics.beginFill(_color, 1);
		b.graphics.drawCircle(0, 0, _radius);
		b.graphics.endFill();
		addChild(b);
		//
	}
}

//BezImgBall運動クラス
import flash.display.*;
import flash.geom.*;
class BezImgBall extends Sprite {

	public var angle:Number;
	public var radian:Number;
	public var pointX:Number;
	public var pointY:Number;
	//番号
	public var count_no:Number;
	//回転方向 0=左 1=右
	public var direction:int;
	//逆転係数
	public var chgFlag:Number = 1;
	//逆転係数2
	public var _chg_x:Number = 1;
	public var _chg_y:Number = 1;
	//画像
	public var bitmap_img:BitmapData;
	public var width_v:Number;
	public var height_v:Number;
	//未使用
	private var _x:Number = 0;
	private var _y:Number = 0;

	public function BezImgBall(_bitmap_img:BitmapData, _width:Number, _height:Number) {

		bitmap_img = _bitmap_img;
		width_v = _width;
		height_v = _height;
		makebox();
	}
	public function makebox():void {
		var b:Sprite = new Sprite();
		//xy
		b.x = 0;
		b.y = 0;
		var bd:BitmapData = new BitmapData(width_v, height_v);
		bd.draw(bitmap_img);
		//XYの位置に注意
		b.graphics.beginBitmapFill(bd, null, false, false);
		b.graphics.drawRoundRect(0, 0, width_v, height_v, 10);
		b.graphics.endFill();
		//中心補正
		b.x = -width_v / 2;
		b.y = -height_v / 2;
		
		addChild(b);
		//
	}
}

//LOADING-Shape
import flash.display.Shape;
class Indicator extends Shape {
	public function Indicator(){
		var i:uint,
		cx:Number, cy:Number,
		numNeedles:uint = 12,
		innerR:Number = 7,
		outerR:Number = 5,
		cAngle:Number = -Math.PI / 2,
		nAngle:Number;
		nAngle = Math.PI * 2 / numNeedles;
		for (i=0; i<numNeedles; i++){
			cAngle += nAngle;
			cx = Math.cos(cAngle) * innerR;
			cy = Math.sin(cAngle) * innerR;
			graphics.moveTo(cx, cy);
			cx = Math.cos(cAngle) * outerR;
			cy = Math.sin(cAngle) * outerR;
			graphics.lineStyle(2, 0xffffff, i/numNeedles);
			graphics.lineTo(cx, cy);
		}
	}
}

使用画像

1 画像80x60 2 3 4 5

三次ベジェ曲線を描くにHAKUHINさんの「3次ベジェ曲線を描画する」記事を参考にしました。

【参考】HAKUHIN's home page: 3次ベジェ曲線を描画する


シュミュレーションテストのボタンなどを削除、コードを簡略化した記事を参考にしてください。

【参考】三次ベジェ曲線と画像の運動: 三次ベジェ曲線で文字を動かす/4


以上です。



[ この記事のURL ]


タグ:series , as3 , ActionScript , flash

[ 三次ベジェ曲線で文字を動かす シリーズ記事 ]

三次ベジェ曲線で文字を動かす/42012.04.21
三次ベジェ曲線で文字を動かす/32012.04.20
三次ベジェ曲線で文字を動かす/22012.04.19
三次ベジェ曲線で文字を動かす/12012.04.17

 

ブログ記事一覧



[1]