POPSブログ

文字を分解してアニメ処理で表示/9

84

  Category:  as32012/04/13 pops 

文字を分解してアニメ処理で表示9。曲線を使用した運動をさせてみました。IN OUT のシュミュレーション(simulation)表示。


文字を分解してアニメ処理で表示9


文字を分解してアニメ処理で表示してみます。曲線を使用した運動をさせてみました。IN OUT を一括して見る事ができます。

曲線を使用した運動のシュミュレーションテスト2。(In Out)

  • 原則、X方向を原点に等速移動、Y方向を振動させることにより、曲線の運動をさせます。
  • 運動の波形は図のように 0-5 の5種類があります。0-4 と 5螺旋は設定が異なりますので運動の性質が違います。
  • 位相の切り替えにより、運動の方向を変えることができます。振幅は固定値ですが、少しランダムに変わります。
  • OUTの場合は処理が反対になるだけで、変更点は少ない。
  • ErasBold、_sans、Impact、3種類の文字とマスクなどを違わせ、切り替え評価が出来るようにしました。

条件を変えて実行してください。


簡単な動作の説明

説明図


1.sin cos関数により上下方向に振動を与え、右より左に移動しているだけです。(Outは反対)
2.Y軸およびX軸で反転させて、方向を違わせています。ここでは位相の切り替えと呼んでいます。
3.アニメ処理はdelay値を変えるためのみ使用され、波形運動はonEnterFrameで処理します。
4.文字のSpriteを運動用のSpriteの中に入れてonEnterFrame処理しています。パーテクルのようなものです。
5.運動用のSpriteの変数をも使用していますので、少し判りにくいかも知れません。
6.直線運動のものと組み合わせる場合はかなり面倒です。(これで直線運動も可能ですが)
7.上記はIn Outの例ですが、Outの場合は処理を反対にすればよい事になります。
8.In Out一括にまとめることも可能ですが、OutのonEnterFrameは別に処理しました。
9.注意、文字にグラデーションマスクを使用した場合に大きさ(scaleX scaleY)を0にしないでください。文字が消滅します。グラデーション部分が復活できないようです。


AS3

FlashTest183.as


//動く文字表示テスト
//FlashTest183
//640x480
//sin関数/In Out
package
{
	
	import flash.display.*;
	import flash.events.*;
	import flash.net.*;
	import flash.geom.*;
	import flash.system.*;
	import flash.utils.*;
	import flash.text.*;

	//TweenLite
	import com.greensock.*;
	import com.greensock.easing.*;
	
	//虹色用
	import frocessing.color.ColorHSV;

	[SWF(width="640", height="480", frameRate="30", backgroundColor="0xFFFFFF")]

	public class FlashTest183 extends Sprite
	{
		
		//補間数(高いほど綺麗で重い)
		static public const	INTERPOLATE:Number = 50;
				
		private var layer0:Sprite;
		private var layer1:Sprite;
		private var layer3:Sprite;
		private var layer4:Sprite;
		private var layer5:Sprite;
		private var container:Sprite;
		private var text_container:Sprite;
		
		//TEXT
		private var tf:TextField;
		private var tf_names:Array = ["通常","1","通常","左","位相 0","回転 0","番号 0","初期位置","350"]
		private var hittf:Array = [];
		//BTN
		private var btn_names:Array = ["透過切替", "拡大切替", "遅延反転", "順序切替", "位相切替", "回転切替", "番号切替", "動作切替", "距離切替"];
		private var hitbtn:Array = [];
		private var fuc_names:Array = [alpha_chg, scale_chg, inversion_chg, delay_chg, xy_chg, rotat_chg, number_chg, setpoint_chg, distance_chg];
		private var btn_1:Sprite;
		private var btn_2:Sprite;
		private var btn_3:Sprite;
		private var btn_4:Sprite;
		private var btn_5:Sprite;
				
		//BIG-MOVE-TEXT-1
		private var mvlinetext1:String;
		private var txline1:int;
		//格納容器1
		private var tx_w1:Array = [];//TextFieldの幅
		private var tx_h1:Array = [];//TextFieldの高さ
		private var sps1:Array = [];//要素Sprite格納容器
		private var cxs1:Array = [];//X位置格納容器
		private var cys1:Array = [];//Y位置格納容器
		private var sin_balls:Array = [];//要素bez_ball格納容器
		private var count_sin:Array = [];//INTERPOLATE減算用配列
		
		//特殊処理大きさ受け渡し
		private var boxWidth_1:Number;
		private var boxHeight_1:Number;
		
		//個別に初期位置を同一にする/1=強制移動 0=移動しない
		private var firstPoint:int = 0;
		private var txs:Array = new Array('固定位置','移動位置');
		private var no:int = 0;
		private var rotatno:int = 0;
		private var rot:Array = [0, 360, -360, 270, -270];
		private var rot_v:Number = 0;//回転数
		//逆転係数
		private var chg_x:Number = 1;
		private var chg_y:Number = 1;
		private var chg_xyno:Number = 0;
		//順序切り替え
		private var delay_no:int = 0;
		private var delay_nm:Array = new Array('左に', '右に', '中から', '外から');
		//グローバルカウント
		private var gl_count:int = 0;
		//背景番号
		private var back_no:int = 0;
		//振幅
		private var swing_x:Number = 100;
		private var swing_y:Number = 100;
		//距離
		private var ball_len_x:Number = 350;
		private var ball_len_y:Number = 350;
		private var balllen_no:int = 0;
		private var balllen_nm:Array = [350, 250, 150];
		//遅延反転
		private var inversion_v:int = 0;
		private var inversion_nm:Array = new Array('通常動作', '交互遅延', '交互反転');
		//scale alpha
		private var scale_v:Number = 1;
		private var scale_no:int = 0;
		private var scale_nm:Array = new Array(1, 3, 5, 10);
		private var alpha_v:Number = 1;//注意固定値
		private var alpha_flag:Number = 0;//alphaを変えるか
		private var alpha_no:int = 0;
		private var alpha_nm:Array = new Array('通常', '透過');
		//No5の進む角度/3.6
		private var angle5:Number = 3.6;
		//OUT実行判定フラグ
		private var outflag:Boolean = false;
		//文字種の設定 0-2
		private var font_no_v:int = 0;
		private var keep_font_no:int = 0;
		private var font_no_mn:Array = ["ErasBold","_sans","Impact"];
		
		//注意 複数種類Embedの場合はそのつどClassを設定する、下のようになる、違ったらコンパイルできない
		[Embed(systemFont = "Impact", fontName = "font", mimeType = "application/x-font")]
		private var embedFont:Class;
		[Embed(systemFont = "Eras Bold ITC", fontName = "font2", mimeType = "application/x-font")]
		private var embedFont2:Class;
		
		public function FlashTest183():void {
			
			//回転数
			rot_v = rot[rotatno];
			//BASE/黒背景
			graphics.beginFill(0x000000);//0x000000
			graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
			graphics.endFill();
			
			//白背景レーヤー
			layer0 = createSquare(0, 0, stage.stageWidth, stage.stageHeight, 0xFFFFFF, 1);
			addChild(layer0);
			layer0.visible = false;
			
			//layer1 文字関係をまとめた
			layer1 = new Sprite();
			addChild(layer1);
			//text
			tf = createTextField(10, 460, stage.stageWidth - 20, 20);
			tf.textColor = 0xCCCCCC;
			tf.text = "";
			tf.selectable = false;
			layer1.addChild(tf);
			
			//ボタンレーヤー
			layer3 = new Sprite();
			addChild(layer3);
			
			//ボタン
			var i:int = 0;
			for (i = 0; i < btn_names.length; i++) {
				var btn:RoundBtn = new RoundBtn(btn_names[i], 13, 0x000000, 60, 20, 0xCCCCCC, 1, 5);
				btn.x = i * 70 + 40;
				btn.y = 15;
				hitbtn[i] = btn;
				layer3.addChild(hitbtn[i]);
				hitbtn[i].addEventListener( MouseEvent.CLICK, fuc_names[i] );
			}
			
			//BTN-1/アニメIN実行
			btn_1 = createRoundBTN("アニメIN", 13, 0x000000, 60, 20, 0xFF69B4, 1, 5);
			btn_1.x = 600;
			btn_1.y = 65;//40
			btn_1.buttonMode = true;
			layer3.addChild(btn_1);
			layer3.visible = false;
			//btn_1にListenerを設定
			btn_1.addEventListener( MouseEvent.CLICK, animate2 );
			
			//BTN-3/アニメOUT実行
			btn_3 = createRoundBTN("アニメOUT", 13, 0x000000, 60, 20, 0x48D1CC, 1, 5);
			btn_3.x = 530;
			btn_3.y = 65;//40
			btn_3.buttonMode = true;
			layer3.addChild(btn_3);
			//btn_3にListenerを設定
			btn_3.addEventListener( MouseEvent.CLICK, animate3 );
			
			//BTN-2/背景切り替え
			layer4 = new Sprite();
			addChild(layer4);
			layer4.visible = false;
			
			btn_2 = createRoundBTN("背景切替", 13, 0x000000, 60, 20, 0xCCCCCC, 1, 5);
			btn_2.x = 600;
			btn_2.y = 465;
			btn_2.buttonMode = true;
			layer4.addChild(btn_2);
			//btn_2にListenerを設定
			btn_2.addEventListener( MouseEvent.CLICK, back_chg );
			
			//BTN-4/文字種切り替え
			btn_4 = createRoundBTN("文字種替", 13, 0x000000, 60, 20, 0xCCCCCC, 1, 5);
			btn_4.x = 460;
			btn_4.y = 465;
			btn_4.buttonMode = true;
			layer4.addChild(btn_4);
			//btn_4にListenerを設定
			btn_4.addEventListener( MouseEvent.CLICK, font_chg );
			
			//BTN-5/文字種切り替え実行
			btn_5 = createRoundBTN("変更実行", 13, 0x000000, 60, 20, 0xFFE4E1, 1, 5);
			btn_5.x = 530;
			btn_5.y = 465;
			btn_5.buttonMode = true;
			layer4.addChild(btn_5);
			//btn_5にListenerを設定
			btn_5.addEventListener( MouseEvent.CLICK, font_reset );
			
			//TEXTレーヤー
			layer5 = new Sprite();
			addChild(layer5);
			//text
			for (i = 0; i < tf_names.length; i++) {
				hittf[i] = createTextField(0, 0, 60, 20);
				hittf[i].x = i * 70 + 10;
				hittf[i].y = 30;
				hittf[i].textColor = 0xCCCCCC;
				hittf[i].text = tf_names[i];
				layer5.addChild(hittf[i]);
			}
			
			//MOVE文字container/ドラッグがテキストにじゃまされて聞きにくいので上にした
			container = createSquare(0, 0, stage.stageWidth, 100, 0xEEEEEE, 0);
			container.x = 200;//5
			container.y = 300;
			addChild(container);
			//文字種をかえてtext_container削除するために入れる通常は不要
			text_container= new Sprite();
			container.addChild(text_container);
						
			//goto-init
			init();
		}
		
		// INIT
		private function init():void {
			
			//drag-Listener/container
			container.addEventListener(MouseEvent.MOUSE_DOWN, onFileMouseDown);
			container.addEventListener(MouseEvent.MOUSE_UP, onFileMouseUp);
			
			//文字初期位置設定なし			
			//goto-main
			main_action();
		}
		
		// MAIN-ACTION
		private function main_action():void {
			//main_action as3 hear
			tf.text = "";
			
			//グラデマスクテキスト MASK-TEXT
			make_MaskText();
			//GOTO-animate
			animate2();
			
		}
		//グラデマスクテキスト MASK-TEXT
		private function make_MaskText():void {
			
			//文字種をかえる
			//No0 embed ErasBold
			var fontsize_v:Number = 30;
			var masktype_v:String = 'none';
			var fonttype_v:String = 'font2';
			var fontspace_v:Number = -6;
			var embedfonts_v:Boolean = true;
			
			//No1 _sans
			if (font_no_v == 1) {
				fontsize_v = 40;
				masktype_v = 'none';
				fonttype_v = '_sans';
				fontspace_v = -6;
				embedfonts_v = false;
			}
			//No2 embed Impact
			if (font_no_v == 2) {
				fontsize_v = 40;
				masktype_v = 'mask';
				fonttype_v = 'font';
				fontspace_v = -6;
				embedfonts_v = true;
			}
			
			//tf.text = "[ _sansでも使用できるように改造 文字の渦運動テスト]";
			mvlinetext1 = "Popsweb.SlideShow";//wonderfl.SlideShow
			//textColor
			var mvtextColor:uint = 0xFFFFFF;
			//length
			txline1 = mvlinetext1.length;
			//位置計算用変数
			var mvbox_pointX:Number = 0;//文字要素のX位置計算用
			var width_b:Number = 0;//前の要素幅保存用
			
			//classで文字を作る
			var box1_v:MakeTextLine = new MakeTextLine(
					mvlinetext1,		// String 全ての文字
					mvtextColor,		// uint 0xFFFFFF 文字色自由
					fontsize_v,			// Number 60 文字サイズ自由
					'rainbow',			// String normal random rainbow 色指定
					masktype_v,			// String mask none グラデーションマスク
					fonttype_v,			// String Embed-fontName font _sans arial _ゴシック
					fontspace_v,		// Number Space -4は引いてあるので差を入力
					embedfonts_v		// embedFonts true false embed文字使用の場合true
			);
				
			//class配列を取り込む
			sps1 = box1_v.txsBoxArrays;//Sprite
			cxs1 = box1_v.cxsArrays;//x位置
			cys1 = box1_v.cysArrays;//y位置
			
			var i:int = 0;
			for (i = 0; i < txline1; i++) {
				
				//文字列位置確定
				sps1[i].x = cxs1[i];
				sps1[i].y = cys1[i];
				//zの指定/embed文字使用の場合は何も書かないこと
				//_sansを使用するためzの指定
				sps1[i].z = 0;
				
				//SinBallクラス生成/Ballクラスに工夫しても、BallクラスにaddChildしても何らかの処理が可能
				var ball:SinBall = new SinBall();
				//識別番号をいれる
				ball.count_no = i;
				sin_balls[i] = ball;
				
				//container text_container	特殊なためtext_containerに入れた
				ball.addChild(sps1[i]);
				//text_containerに入れた
				text_container.addChild(ball);
				//直接containerに入れる場合
				//container.addChild(ball);
				//
			}
			
			//重要、大きさ
			boxWidth_1 = sps1[txline1 - 1].x + sps1[txline1 - 1].width / 2;
			boxHeight_1 = sps1[0].height;
			//
		}
		
		//透過切替,拡大切替,遅延反転,順序切替,位相切替,回転切替,番号切替,動作切替,距離切替/ 背景切替 文字種切替
		//透過切り替え
		private function alpha_chg(e:MouseEvent):void {
			alpha_no ++;
			if (alpha_no > 1) { alpha_no = 0; }
			if (alpha_no == 0 ) { alpha_flag = 0; }
			if (alpha_no == 1 ) { alpha_flag = 1; }
			hittf[0].text = "" + alpha_nm[alpha_no];
		}
		//拡大切り替え
		private function scale_chg(e:MouseEvent):void {
			scale_no ++;
			if (scale_no > 3) { scale_no = 0; }
			scale_v = scale_nm[scale_no];
			hittf[1].text = "" + scale_v;
		}
		//反転遅延
		private function inversion_chg(e:MouseEvent):void {
			inversion_v ++;
			if (inversion_v > 2) { inversion_v = 0; }
			hittf[2].text = "" + inversion_nm[inversion_v];
		}
		//順序切り替え
		private function delay_chg(e:MouseEvent):void {
			delay_no ++;
			if (delay_no > 3) { delay_no = 0; }
			hittf[3].text = "" + delay_nm[delay_no];
		}
		//位相切り替え
		private function xy_chg(e:MouseEvent):void {
			chg_xyno ++;
			if (chg_xyno > 3) { chg_xyno = 0; }
			//位相切り替え
			if (chg_xyno == 0) { chg_x = 1; chg_y = 1; }
			if (chg_xyno == 1) { chg_x = 1; chg_y = -1; }
			if (chg_xyno == 2) { chg_x = -1; chg_y = 1; }
			if (chg_xyno == 3) { chg_x = -1; chg_y = -1; }
			hittf[4].text = "" + chg_xyno;
		}
		//回転切り替え
		private function rotat_chg(e:MouseEvent):void {
			//0 360 -360 180 -180
			rotatno ++;
			if (rotatno > 4 ) { rotatno = 0; }
			rot_v = rot[rotatno];
			hittf[5].text = "" + rot_v;
		}
		//番号切り替え
		private function number_chg(e:MouseEvent):void {
			//0-5 5螺旋
			no ++;
			if (no > 5 ) { no = 0; }
			hittf[6].text = "" + no;
		}
		//初期位置切り替え
		private function setpoint_chg(e:MouseEvent):void {
			//
			firstPoint ++;
			if (firstPoint > 1) { firstPoint = 0; }
			//if (firstPoint == 1) { firstPoint = 0; } else { firstPoint = 1; }
			hittf[7].text = "" + txs[firstPoint];
		}
		//距離切り替え
		private function distance_chg(e:MouseEvent):void {
			balllen_no ++;
			if (balllen_no > 2) { balllen_no = 0; }
			ball_len_x = balllen_nm[balllen_no] * 1;
			ball_len_y = balllen_nm[balllen_no] * 1;
			hittf[8].text = "" + balllen_nm[balllen_no];
		}
		
		//背景切り替え
		private function back_chg(e:MouseEvent):void {
			if (back_no == 0) { back_no = 1; layer0.visible = true;}
			else { back_no = 0; layer0.visible = false; }
		}
		//文字種切り替え
		private function font_chg(e:MouseEvent):void {
			//0-2
			font_no_v ++;
			if (font_no_v > 2 ) { font_no_v = 0; }
			tf.text = "選定文字 " + font_no_mn[font_no_v] + " [変更実行]ボタンを押す";
		}
		
		//文字種切り替え実行
		private function font_reset(e:MouseEvent = null ):void {
			//同じなら実行しない
			if (keep_font_no == font_no_v) { tf.text = "現在設定と同一文字のため文字種切り替え中止"; return; }
			//コンテナ削除/新規作成
			container.removeChild(text_container);
			text_container = new Sprite();
			container.addChild(text_container);
			//保存更新
			keep_font_no = font_no_v;
			tf.text = "文字種切り替え実行(アニメIN) 選定文字 " + font_no_mn[font_no_v];
			//文字読み込み
			make_MaskText();
			//整列実行/GOTO-animate
			animate2();
			//
		}
		
		//animate2/IN
		private function animate2( e:MouseEvent = null ):void {
			
			tf.text = "SIN曲線 アニメ実行中です";
			//OUT実行判定フラグ
			outflag = false;
			
			//ボタン非表示/アニメ途中おされるとくるう
			layer3.visible = false;
			layer4.visible = false;
			
			//no = Math.random() * 6;
			//順序切り替え
			var delay_v:Number = 0;
			var delay_total:Number = txline1 * 0.5;
			var txline_mv:Number = (txline1 - 1) / 2;
			var flag3:int = 1;
			//alpha
			var alpha_v2:Number = 1;
			//変化の確率 inversion_v
			//var chgflag:Number = Math.floor(Math.random() * 6);
			//中外の場合加算する数値
			var d_chg_v:Number = Math.floor(Math.random() * 4 ) * 0.25;
			//alpha
			if (alpha_flag == 0 ) { alpha_v2 = 1; }
			if (alpha_flag == 1 ) { alpha_v2 = 0; }
			
			var i:int = 0;
			for (i = 0; i < txline1; i++) {
				
				//中の文字位置を00にセットする位置情報は外のspiral_ballsに設定した
				sps1[i].x = 0;
				sps1[i].y = 0;
				
				//見えない場用に移動
				sin_balls[i].x = (stage.stageWidth + ball_len_x + cxs1[i]) * chg_x;
				sin_balls[i].y = 0;
				
				//scale
				sin_balls[i].scaleX = 0.1;
				sin_balls[i].scaleY = 0.1;
				
				//INTERPOLATE減算用配列
				count_sin[i] = INTERPOLATE;//50
				
				//delay値の変化/中外4種類
				delay_v = i * 0.5;//左
				if (delay_no == 1) { delay_v = delay_total - i * 0.5; }//右
				if (delay_no == 2) { delay_v = Math.abs((i + d_chg_v) - txline_mv)*0.5; }//中
				if (delay_no == 3) { delay_v = (delay_total / 2) - Math.abs((i + d_chg_v) - txline_mv) * 0.5; }//外
				
				//遅延フラグクリア
				sin_balls[i]._chg_x = 1;
				sin_balls[i]._chg_y = 1;
				
				//遅延inversion_v/chgflag
				if (inversion_v == 1) {
					if (flag3 < 0) { delay_v += 2.25; }
				}
				//逆転inversion_v/chgflag
				if (inversion_v == 2) {
					if (flag3 < 0) {
						sin_balls[i]._chg_x = -1;
						sin_balls[i]._chg_y = -1;
					}
				}
				//scale
				if (scale_v < 1) { scale_v = 1; }
				
				//グローバルカウント
				gl_count = 0;
				
				//TEST sin
				sin_balls[i].radian = 0;
				//振幅
				swing_y = Math.floor(Math.random() * 5) * 10 + 50;
				
				//中を拡大
				sps1[i].scaleX = scale_v;
				sps1[i].scaleY = scale_v;
				
				//遅延させるTweenLite
				var myTween:TweenLite = new TweenLite(sin_balls[i],0.5,{delay:delay_v, scaleX:1, scaleY:1, alpha:alpha_v2, onComplete:tw_onComplete,onCompleteParams:[i]});
				flag3 *= -1;
			}
		}
		
		//animate3/OUT
		private function animate3( e:MouseEvent = null ):void {
			
			tf.text = "SIN曲線 アニメ OUT 実行中です";
			layer3.visible = false;
			layer4.visible = false;
			//OUT実行判定フラグ
			outflag = true;
			
			//順序切り替え
			var delay_v:Number = 0;
			var delay_total:Number = txline1 * 0.5;
			var txline_mv:Number = (txline1 - 1) / 2;
			var flag3:int = 1;
			//alpha
			var alpha_v2:Number = 1;
			//中外の場合加算する数値
			var d_chg_v:Number = Math.floor(Math.random() * 4 ) * 0.25;
			//alpha
			if (alpha_flag == 0 ) { alpha_v2 = 1; }
			if (alpha_flag == 1 ) { alpha_v2 = 0; }
			
			var i:int = 0;
			for (i = 0; i < txline1; i++) {
				
				//中の文字位置を00にセット
				sps1[i].x = 0;
				sps1[i].y = 0;
				
				//規定の位置
				sin_balls[i].x = cxs1[i];
				sin_balls[i].y = 0;
				//scale
				sin_balls[i].scaleX = 1;
				sin_balls[i].scaleY = 1;
				//alpha重要
				sin_balls[i].alpha = 1;
				
				//INTERPOLATE加算算用配列
				count_sin[i] = 0;//0
				
				//delay値の変化/中外4種類
				delay_v = i * 0.5;//左
				if (delay_no == 1) { delay_v = delay_total - i * 0.5; }//右
				if (delay_no == 2) { delay_v = Math.abs((i + d_chg_v) - txline_mv)*0.5; }//中
				if (delay_no == 3) { delay_v = (delay_total / 2) - Math.abs((i + d_chg_v) - txline_mv) * 0.5; }//外
				
				//遅延フラグクリア
				sin_balls[i]._chg_x = 1;
				sin_balls[i]._chg_y = 1;
				
				//遅延inversion_v/chgflag
				if (inversion_v == 1) {
					if (flag3 < 0) { delay_v += 2.25; }
				}
				//逆転inversion_v/chgflag
				if (inversion_v == 2) {
					if (flag3 < 0) {
						sin_balls[i]._chg_x = -1;
						sin_balls[i]._chg_y = -1;
					}
				}
				//グローバルカウント
				gl_count = 0;
				//TEST sin
				sin_balls[i].radian = 0;
				//振幅
				swing_y = Math.floor(Math.random() * 5) * 10 + 50;
				//中を拡大1
				sps1[i].scaleX = 1;
				sps1[i].scaleY = 1;
				
				//遅延させるだけが目的
				var myTween:TweenLite = new TweenLite(sin_balls[i],0.5,{delay:delay_v, scaleX:1, scaleY:1, alpha:1, onComplete:out_onComplete,onCompleteParams:[i]});
				flag3 *= -1;
			}
		}
		
		//TweenLite-onComplete IN
		private function tw_onComplete(param1:int):void {
			//onEnterFrame処理
			sin_balls[param1].addEventListener(Event.ENTER_FRAME, onEnterFrame_sin);
		}
		//TweenLite-onComplete OUT
		private function out_onComplete(param1:int):void {
			sin_balls[param1].addEventListener(Event.ENTER_FRAME, onEnterFrame_sinout);
		}
		
		//ball onEnterFrame IN
		private function onEnterFrame_sin(e:Event):void {
			//
			var count:Number = INTERPOLATE;//50
			//as Ballで問題なくコンパイル/thisは使えない
			var mv_ball:SinBall = e.currentTarget as SinBall;
			var ball_no:int = mv_ball.count_no;
			
			if (gl_count < txline1) {
				//回転rot_vをcountでわる
				mv_ball.rotation += rot_v / count;
				//mv_ball.rotation = -30;
				
				//大きいなら
				if (sps1[ball_no].scaleX > 1) {
					sps1[ball_no].scaleX -= (scale_v - 1) / count;
					sps1[ball_no].scaleY -= (scale_v - 1) / count;
				}
				//if (alpha_flag) {
					//mv_ball.alpha += alpha_v / count;
				//}
				//alphaなら
				if (mv_ball.alpha < 1) {
					mv_ball.alpha += alpha_v / count;
				}
					
				//最後0になるように初めに減算する(INTERPOLATE)
				//INTERPOLATE減算用配列
				count_sin[ball_no] -= 1;
				
				//保存係数
				var cx:Number =	mv_ball._chg_x;
				var cy:Number =	mv_ball._chg_y;
				
				//X方向の計算
				var by:Number = (0 * count_sin[ball_no] / count);//まだ計算なし
				var bx:Number = (ball_len_x * count_sin[ball_no] / count);
				if (no != 5) {mv_ball.x = (bx * chg_x * cx + cxs1[ball_no])};
				if (firstPoint == 1) { sps1[ball_no].x = bx * chg_x * cx; }//中移動
				//螺旋X angle=3.6
				if (no == 5) {
					mv_ball.x = (Math.cos(angle5 * count_sin[ball_no] / count) * ball_len_x * count_sin[ball_no] / count) * chg_x * cx + cxs1[ball_no];
				}
				
				//sin Y方向の計算
				mv_ball.radian += mv_ball.radian_v/count/stage.frameRate;
				if (no == 0) {
					mv_ball.y = (Math.sin(mv_ball.radian) * swing_y + by) * chg_y*cy;//外振幅プラス
				}
				if (no == 1) {
					(mv_ball.y = Math.sin(mv_ball.radian/2) * swing_y * -1) * chg_y*cy;
				}
				if (no == 2) {
					mv_ball.y = Math.sin(mv_ball.radian/2) * swing_y * chg_y*cy;
				}
				//bxの幅基準
				//cos Y方向の計算
				if (no == 3) {
					mv_ball.y = Math.cos(mv_ball.radian/2) * bx * chg_y*cy;
				}
				//cos sinY/方向の計算振幅が減衰
				if (no == 4) {
					mv_ball.y = (Math.cos(mv_ball.radian/2) - Math.sin(mv_ball.radian)) * bx * chg_y*cy;
				}
				//螺旋 angle=3.6
				if (no == 5) {
					mv_ball.y = (Math.sin(angle5 * count_sin[ball_no] / count) * ball_len_x * count_sin[ball_no] / count) * chg_y * cy;
				}
				
				//removeEventListener
				if (count_sin[ball_no] <= 0) {
					
					//グローバルカウント/反転するとカウントが正確でないのでこちらで判定
					gl_count ++;
					//回転0
					sps1[ball_no].rotation = 0;
					mv_ball.rotation = 0;
					mv_ball.y = 0;
					//
					mv_ball.scaleX = 1;
					mv_ball.scaleY = 1;
					mv_ball.alpha = 1;
					
					//どちらでもOK
					//sin_balls[ball_no].removeEventListener(Event.ENTER_FRAME, onEnterFrame_sin);
					mv_ball.removeEventListener(Event.ENTER_FRAME, onEnterFrame_sin);
					//最後になったらボタン表示
					//if (mv_ball.count_no == txline1 - 1) { show_button(); }
					if (gl_count == txline1) { show_button(); }
				}
				
			}
		}
		
		//ball onEnterFrame OUT
		private function onEnterFrame_sinout(e:Event):void {
			//
			var count:Number = INTERPOLATE;//50
			//as Ballで問題なくコンパイル/thisは使えない
			var mv_ball:SinBall = e.currentTarget as SinBall;
			var ball_no:int = mv_ball.count_no;
			
			if (gl_count < txline1) {
				//回転rot_vをcountでわる
				mv_ball.rotation += rot_v / count;
				
				//小さいなら
				if (sps1[ball_no].scaleX < scale_v) {
					sps1[ball_no].scaleX += (scale_v - 1) / count;
					sps1[ball_no].scaleY += (scale_v - 1) / count;
				}
				if (alpha_flag) {
					mv_ball.alpha -= alpha_v / count;
				}
				
				//INTERPOLATE加算用配列
				count_sin[ball_no] += 1;
				
				//保存係数
				var cx:Number =	mv_ball._chg_x;
				var cy:Number =	mv_ball._chg_y;
				
				//X方向の計算
				var by:Number = (0 * count_sin[ball_no] / count);//まだ計算なし
				var bx:Number = (ball_len_x * count_sin[ball_no] / count);
				if (no != 5) {mv_ball.x = (bx * chg_x * cx + cxs1[ball_no])};
				if (firstPoint == 1) { sps1[ball_no].x = bx * chg_x * cx; }//中移動
				//螺旋X angle=3.6
				if (no == 5) {
					mv_ball.x = (Math.cos(angle5 * count_sin[ball_no] / count) * ball_len_x * count_sin[ball_no] / count) * chg_x * cx + cxs1[ball_no];
				}
				
				//sin Y方向の計算
				mv_ball.radian += mv_ball.radian_v/count/stage.frameRate;
				if (no == 0) {
					mv_ball.y = (Math.sin(mv_ball.radian) * swing_y + by) * chg_y*cy;//外振幅プラス
				}
				if (no == 1) {
					(mv_ball.y = Math.sin(mv_ball.radian/2) * swing_y * -1) * chg_y*cy;
				}
				if (no == 2) {
					mv_ball.y = Math.sin(mv_ball.radian/2) * swing_y * chg_y*cy;
				}
				//bxの幅基準
				//cos Y方向の計算
				if (no == 3) {
					mv_ball.y = Math.cos(mv_ball.radian/2) * bx * chg_y*cy;
				}
				//cos sinY/方向の計算振幅が減衰
				if (no == 4) {
					mv_ball.y = (Math.cos(mv_ball.radian/2) - Math.sin(mv_ball.radian)) * bx * chg_y*cy;
				}
				//螺旋 angle=3.6
				if (no == 5) {
					mv_ball.y = (Math.sin(angle5 * count_sin[ball_no] / count) * ball_len_x * count_sin[ball_no] / count) * chg_y * cy;
				}
				
				//removeEventListener
				if (count_sin[ball_no] >= INTERPOLATE) {
					
					//グローバルカウント/反転するとカウントが正確でないのでこちらで判定
					gl_count ++;
					//回転0
					sps1[ball_no].rotation = 0;
					mv_ball.rotation = 0;
					mv_ball.y = 0;
					//OUTだけの場合拡大のままだと影響があるので中も戻す
					sps1[ball_no].scaleX = 1;
					sps1[ball_no].scaleY = 1;
					//重要、scaleを0にすると中のグラデが壊れるのでalphaを変えた
					mv_ball.scaleX = 1;
					mv_ball.scaleY = 1;
					mv_ball.alpha = 0;
					
					mv_ball.removeEventListener(Event.ENTER_FRAME, onEnterFrame_sinout);
					//最後になったらボタン表示
					if (gl_count == txline1) { show_button(); }
				}
				
			}
		}
		
		//ボタン表示作動中にボタンを押すと崩れるので非表示にしている
		private function show_button ():void {
			gl_count = 0;
			//OUT実行判定フラグ/連続してOUT実行をさせない
			//マスク文字の場合こわれてしまうのでINを実行させる
	//一応解決したので設定していない
	//if (outflag) { btn_3.visible = false; }
	//else { btn_3.visible = true; }
			
			layer3.visible = true;
			layer4.visible = true;
			tf.text = "SIN曲線 移動完了 ドラッグポイント x:" + container.x + " y:" + container.y;
		}
		
		//簡易ドラッグ設定/注意Sprite容器でなければ機能しない
		private function onFileMouseDown(event:MouseEvent):void {
			event.currentTarget.startDrag();
		}
		private function onFileMouseUp(event:MouseEvent):void {
			event.currentTarget.stopDrag();
			tf.text = "x:" + container.x + " y:" + container.y;
		}

		//create-box
		private function createSquare(x:Number, y:Number, width:Number, height:Number, color:Number, alpha:Number):Sprite {
			var s:Sprite = new Sprite();
			s.graphics.beginFill(color, alpha);
			s.graphics.drawRect(x, y, width, height);
			s.graphics.endFill();
			//addChild(s);
			return s;
		}
		//create-text
		private function createTextField(x:Number, y:Number, width:Number, height:Number):TextField {
			var result:TextField = new TextField();
			result.x = x;
			result.y = y;
			result.width = width;
			result.height = height;
			//addChild(result);
			return result;
		}
		//create-RoundBTN/原点中央ボタンモードなど訂正
		private function createRoundBTN(text:String, t_size:int, t_color:uint, width:Number, height:Number, color:uint, alpha:Number, round:Number):Sprite {
			var rsbt:Sprite = new Sprite();
			rsbt.graphics.beginFill(color, alpha);
			rsbt.graphics.drawRoundRect(-width/2, -height/2, width, height, round);
			rsbt.graphics.endFill();
			addChild(rsbt);
			var r:TextField = new TextField();
			var fmt:TextFormat = new TextFormat('_ゴシック', t_size, null, null, null, null, null, null, TextFormatAlign.CENTER );
			r.defaultTextFormat = fmt;
			r.textColor = t_color;
			r.selectable = false;
			//r.autoSize = TextFieldAutoSize.LEFT;
			r.text = text;
			r.width = width;
			r.height = height;
			r.x = -width / 2;
			r.y = -height / 2 + 2;
			r.mouseEnabled = false;
			//buttonMode
			rsbt.buttonMode = true;
			rsbt.addChild(r);
			return rsbt;
		}
	}
}

//RoundBtnクラス/原点中央ボタンモードなど訂正
import flash.display.*;
import flash.utils.*;
import flash.text.*;
class RoundBtn extends Sprite {
	//
	public function RoundBtn(text:String, t_size:int, t_color:uint, width:Number, height:Number, color:uint, alpha:Number, round:Number):void {
			var rsbt:Sprite = new Sprite();
			rsbt.graphics.beginFill(color, alpha);
			rsbt.graphics.drawRoundRect(-width/2, -height/2, width, height, round);
			rsbt.graphics.endFill();
			addChild(rsbt);
			var r:TextField = new TextField();
			var fmt:TextFormat = new TextFormat('_ゴシック', t_size, null, null, null, null, null, null, TextFormatAlign.CENTER );
			r.defaultTextFormat = fmt;
			r.textColor = t_color;
			r.selectable = false;
			//r.autoSize = TextFieldAutoSize.LEFT;
			r.text = text;
			r.width = width;
			r.height = height;
			r.x = -width / 2;
			r.y = -height / 2 + 2;
			r.mouseEnabled = false;
			//buttonMode
			rsbt.buttonMode = true;
			rsbt.addChild(r);
	}
}

//SinBall運動クラス
import flash.display.*;
class SinBall extends Sprite {

	//番号
	public var count_no:Number;
	//回転方向 0=左 1=右
	public var direction:int;
	//逆転係数
	public var chgFlag:Number = 1;
	//逆転係数2
	public var _chg_x:Number = 1;
	public var _chg_y:Number = 1;
	//TEST
	public var radian:Number = 0;
	public var radian_v:Number = 180;
	//未使用
	private var _x:Number = 0;
	private var _y:Number = 0;

	public function SinBall() {
		var b:Sprite = new Sprite();
		//xy
		b.x = 0;
		b.y = 0;
		addChild(b);
	}
}

//複数文字の グラデーションマスク クラス
import flash.display.*;
import flash.geom.*;
import flash.text.*;
import flash.system.*;
import flash.utils.*;
//虹色用
import frocessing.color.ColorHSV;

class MakeTextLine extends Sprite {
	//受け渡し配列変数
	public var txsBoxArrays:Array;
	public var cxsArrays:Array;
	public var cysArrays:Array;
	//変数
	private var tx:String;
	private var txs:String;
	private var color:uint;
	private var color_type:String;
	private var mask_type:String;
	private var font_name:String;
	private var font_size:Number;
	private var embed:Boolean;
	private var space:Number;
	private var space_v:Number = -4;
	private var len:Number;
	private var sps:Array;//要素Sprite格納容器
	
	public function MakeTextLine(_txs:String, _color:uint, _font_size:Number, _color_type:String, _mask_type:String, _font_name:String, _space:Number, _embed:Boolean = false):void {
		//変数の代入
		txs = _txs;
		color = _color;
		color_type = _color_type;
		mask_type = _mask_type;
		font_name = _font_name;
		font_size = _font_size;
		embed = _embed;
		space = _space;
		
		//受け渡し配列変数クリア
		txsBoxArrays = [];
		cxsArrays = [];
		cysArrays = [];
		sps = [];
		//作成
		maskText();
	}
	private function maskText():void {
		
			var mvlinetext:String = txs;
			var txline:int;
			var mvtext_pX:Number = 0;//先頭文字位置調整用
			var mvtext_pY:Number = 0;//先頭文字位置調整用
			var mvtext_len:Number = 0;//字位置調整用
			var cx:Number = 0;
			var cy:Number = 0;
			var cxs:Array = [];
			var cys:Array = [];
			var spase_t:Number = space_v + space;//文字間のスペース
			//length
			txline = mvlinetext.length;
			//1=虹色にそめる 0=指定色 2=ランダム色にそめるrandom rainbow 
			var rainbow_colored:int = 0;
			if (color_type == 'rainbow') {rainbow_colored = 1;}
			if (color_type == 'random') {rainbow_colored = 2;}
			//基本textColor
			var mvtextColor:uint = color;
			//虹色にそめる変数
			var nAngle:Number = Math.PI * 2 / txline;
			var cAngle:Number = 0;
			
			for (var i:int = 0; i < txline; i++) {
				//虹色にそめる
				if (rainbow_colored == 1) {
					//frocessingで虹色を求める
					var hsv:ColorHSV = new ColorHSV(0, 1, 1, 1);
					hsv.h = cAngle / Math.PI * 180;
					//虹色を取得受け渡す
					mvtextColor = hsv.value;
					cAngle += nAngle;
				}
				//ランダム色に染める/問題あるときはランダム色
				if (rainbow_colored > 1) {
					//ランダム色
					mvtextColor = 0xFFFFFF * Math.random();//random
				}
				//文字を作る
				var mvtext_sp:Sprite = maskBox(mvlinetext.charAt(i), mvtextColor, font_size, mask_type, font_name, embed);
				//表示位置決定のため半分の間隔をプラスする、中心補正
				mvtext_len += mvtext_sp.width / 2;//文字間補正1
				//位置確定
				cxs[i] = cx = mvtext_pX + mvtext_len;//
				cys[i] = cy = 0;
				//出来上がった文字BOX、mvtext_spを保存
				sps[i] = mvtext_sp;
				//次の文字位置のため、最後に現在文字の半分の間隔をプラスする
				mvtext_len += (mvtext_sp.width / 2) + spase_t;
			}
			
			//配列を受け渡し配列に代入
			txsBoxArrays = sps;
			cxsArrays = cxs;
			cysArrays = cys;

	}
	private function maskBox(tx:String, color:uint, font_size:Number, mask_type:String, font_name:String, embed:Boolean):Sprite {
		//maskBox
		var result:TextField = new TextField();
		var fmt:TextFormat = new TextFormat();
		//CENTERにするとスペースがなくなる
		fmt.size = font_size;//60
		fmt.font = font_name;
		fmt.rightMargin = 0;
		fmt.leftMargin = 0;
		result.defaultTextFormat = fmt;
		result.text = tx;
		result.autoSize = TextFieldAutoSize.LEFT;//LEFT autoSizeでなければならない
		result.textColor = color;
		result.background = false;
		result.embedFonts = embed;
		//result.condenseWhite = false;//HTMLの場合有効
		result.selectable = false;
		//中心補正
		result.x = -result.width / 2;
		result.y = -result.height / 2;
		//基盤Spriteを作る
		var _text_sp:Sprite = new Sprite();
		
		//マスク処理
		if (mask_type=='mask') {
			//MASK/ShapeでもSpriteでもどちらでもOKのようだ
			var text_mask:Shape = new Shape();	
			//MASK,マスク透過グラデを作る
			var mtx:Matrix = new Matrix();
			mtx.createGradientBox(result.width, result.height, 0, 0, 0);
			//ずらした
			text_mask.graphics.beginGradientFill(
				GradientType.LINEAR,
				[0x00, 0x00],
				[1, 0],
				[50, 240],//[0, 255]
				mtx
			);
			text_mask.graphics.drawRect(0, 0, result.width, result.height);
			
			//マスク中心補正
			text_mask.x = -result.width / 2;
			text_mask.y = -result.height / 2;
			//マスクChildは必要
			_text_sp.addChild(text_mask);
			//グラデマスク実行 TextFieldに直接実行してもOK
			result.mask = text_mask;
			//cacheAs
			result.cacheAsBitmap = true;
			text_mask.cacheAsBitmap = true;
		}
		//Child
		_text_sp.addChild(result);
		//重要
		addChild(_text_sp);
		return _text_sp;
	}

}

FlashTest182.asと比較して、FlashTest183.asは、文字種の変更のためにcontainerの中にtext_container(Sprite)が入っています。簡単に文字の部分を削除するためです。
通常は、文字種の変更などありませんので、text_containerなしの構造にしてください。


シュミュレーションテストのボタンなどを削除、「In 用」「Out 用」のコードを簡略化した記事を参考にしてください。

【参考】曲線運動「In 用」の簡略化スクリプト: 文字を分解してアニメ処理で表示10

【参考】曲線運動「Out 用」の簡略化スクリプト: 文字を分解してアニメ処理で表示11


複数の文字列を一括して処理するクラス。詳細は、次ぎのページを参照ください。

【参考】複数の文字列を一括して処理: 文字を分解してアニメ処理で表示6


以上です。



[ この記事のURL ]


タグ:series , as3 , ActionScript , flash

[ 文字を分解してアニメ処理で表示 シリーズ記事 ]

サイン曲線で画像を動かすテストです/22012.04.22
サイン曲線で画像を動かすテストです/12012.04.21
三次ベジェ曲線で文字を動かす/22012.04.19
三次ベジェ曲線で文字を動かす/12012.04.17
文字を分解してアニメ処理で表示/112012.04.16
文字を分解してアニメ処理で表示/102012.04.14
文字を分解してアニメ処理で表示/92012.04.13
文字を分解してアニメ処理で表示/82012.04.12
文字を分解してアニメ処理で表示/72012.04.08
文字を分解してアニメ処理で表示/62012.04.07
文字を分解してアニメ処理で表示/52012.04.06
文字を分解してアニメ処理で表示/42012.04.05
文字を分解してアニメ処理で表示/32012.04.04
文字を分解してアニメ処理で表示/22012.04.03
文字を分解してアニメ処理で表示/12012.04.02

 

ブログ記事一覧



[1]